forked from mirrors/nixpkgs
159 lines
3.4 KiB
Nix
159 lines
3.4 KiB
Nix
{ config
|
|
, lib
|
|
, stdenv
|
|
, fetchFromGitHub
|
|
, addOpenGLRunpath
|
|
, cmake
|
|
, fdk_aac
|
|
, ffmpeg_4
|
|
, jansson
|
|
, libjack2
|
|
, libxkbcommon
|
|
, libpthreadstubs
|
|
, libXdmcp
|
|
, qtbase
|
|
, qtsvg
|
|
, speex
|
|
, libv4l
|
|
, x264
|
|
, curl
|
|
, wayland
|
|
, xorg
|
|
, pkg-config
|
|
, libvlc
|
|
, mbedtls
|
|
, wrapGAppsHook
|
|
, scriptingSupport ? true
|
|
, luajit
|
|
, swig
|
|
, python3
|
|
, alsaSupport ? stdenv.isLinux
|
|
, alsa-lib
|
|
, pulseaudioSupport ? config.pulseaudio or stdenv.isLinux
|
|
, libpulseaudio
|
|
, libcef
|
|
, pciutils
|
|
, pipewireSupport ? stdenv.isLinux
|
|
, pipewire
|
|
, libdrm
|
|
, libajantv2
|
|
, librist
|
|
, srt
|
|
, qtwayland
|
|
, wrapQtAppsHook
|
|
, ...
|
|
}:
|
|
|
|
let
|
|
inherit (lib) optional optionals;
|
|
|
|
in
|
|
stdenv.mkDerivation rec {
|
|
pname = "obs-studio";
|
|
version = "28.1.2";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "obsproject";
|
|
repo = "obs-studio";
|
|
rev = version;
|
|
sha256 = "sha256-M5UEOtdzXBVY0UGfwWx3MsM28bJ1EcVPl8acWXWV0lg=";
|
|
fetchSubmodules = true;
|
|
};
|
|
|
|
patches = [
|
|
# Lets obs-browser build against CEF 90.1.0+
|
|
./Enable-file-access-and-universal-access-for-file-URL.patch
|
|
./Provide-runtime-plugin-destination-as-relative-path.patch
|
|
];
|
|
|
|
nativeBuildInputs = [
|
|
addOpenGLRunpath
|
|
cmake
|
|
pkg-config
|
|
wrapGAppsHook
|
|
wrapQtAppsHook
|
|
]
|
|
++ optional scriptingSupport swig;
|
|
|
|
buildInputs = [
|
|
curl
|
|
fdk_aac
|
|
ffmpeg_4
|
|
jansson
|
|
libcef
|
|
libjack2
|
|
libv4l
|
|
libxkbcommon
|
|
libpthreadstubs
|
|
libXdmcp
|
|
qtbase
|
|
qtsvg
|
|
speex
|
|
wayland
|
|
x264
|
|
libvlc
|
|
mbedtls
|
|
pciutils
|
|
libajantv2
|
|
librist
|
|
srt
|
|
qtwayland
|
|
]
|
|
++ optionals scriptingSupport [ luajit python3 ]
|
|
++ optional alsaSupport alsa-lib
|
|
++ optional pulseaudioSupport libpulseaudio
|
|
++ optionals pipewireSupport [ pipewire libdrm ];
|
|
|
|
# Copied from the obs-linuxbrowser
|
|
postUnpack = ''
|
|
mkdir -p cef/Release cef/Resources cef/libcef_dll_wrapper/
|
|
for i in ${libcef}/share/cef/*; do
|
|
cp -r $i cef/Release/
|
|
cp -r $i cef/Resources/
|
|
done
|
|
cp -r ${libcef}/lib/libcef.so cef/Release/
|
|
cp -r ${libcef}/lib/libcef_dll_wrapper.a cef/libcef_dll_wrapper/
|
|
cp -r ${libcef}/include cef/
|
|
'';
|
|
|
|
# obs attempts to dlopen libobs-opengl, it fails unless we make sure
|
|
# DL_OPENGL is an explicit path. Not sure if there's a better way
|
|
# to handle this.
|
|
cmakeFlags = [
|
|
"-DCMAKE_CXX_FLAGS=-DDL_OPENGL=\\\"$(out)/lib/libobs-opengl.so\\\""
|
|
"-DOBS_VERSION_OVERRIDE=${version}"
|
|
"-Wno-dev" # kill dev warnings that are useless for packaging
|
|
# Add support for browser source
|
|
"-DBUILD_BROWSER=ON"
|
|
"-DCEF_ROOT_DIR=../../cef"
|
|
"-DENABLE_JACK=ON"
|
|
];
|
|
|
|
dontWrapGApps = true;
|
|
preFixup = ''
|
|
qtWrapperArgs+=(
|
|
--prefix LD_LIBRARY_PATH : "${lib.makeLibraryPath [ xorg.libX11 libvlc ]}"
|
|
''${gappsWrapperArgs[@]}
|
|
)
|
|
'';
|
|
|
|
postFixup = lib.optionalString stdenv.isLinux ''
|
|
addOpenGLRunpath $out/lib/lib*.so
|
|
addOpenGLRunpath $out/lib/obs-plugins/*.so
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Free and open source software for video recording and live streaming";
|
|
longDescription = ''
|
|
This project is a rewrite of what was formerly known as "Open Broadcaster
|
|
Software", software originally designed for recording and streaming live
|
|
video content, efficiently
|
|
'';
|
|
homepage = "https://obsproject.com";
|
|
maintainers = with maintainers; [ jb55 MP2E V miangraham ];
|
|
license = licenses.gpl2Plus;
|
|
platforms = [ "x86_64-linux" "i686-linux" "aarch64-linux" ];
|
|
mainProgram = "obs";
|
|
};
|
|
}
|