forked from mirrors/nixpkgs
01c7edd4f4
Semi-automatic update generated by https://github.com/ryantm/nixpkgs-update tools. This update was made based on information from https://repology.org/metapackage/godot/versions. These checks were done: - built on NixOS - Warning: no invocation of /nix/store/wavl2nim76s48xwjpq95wsxgsxvrb4sn-godot-3.0.4/bin/godot had a zero exit code or showed the expected version - 0 of 1 passed binary check by having a zero exit code. - 0 of 1 passed binary check by having the new version present in output. - found 3.0.4 with grep in /nix/store/wavl2nim76s48xwjpq95wsxgsxvrb4sn-godot-3.0.4 - directory tree listing: https://gist.github.com/bdbe8596726721b6c715d84c81579c57 - du listing: https://gist.github.com/6235762e4766106db266094344e36ae7
70 lines
2 KiB
Nix
70 lines
2 KiB
Nix
{ stdenv, lib, fetchFromGitHub, scons, pkgconfig, libX11, libXcursor
|
|
, libXinerama, libXrandr, libXrender, libpulseaudio ? null
|
|
, libXi ? null, libXext, libXfixes, freetype, openssl
|
|
, alsaLib, libGLU, zlib, yasm ? null }:
|
|
|
|
let
|
|
options = {
|
|
touch = libXi != null;
|
|
pulseaudio = false;
|
|
};
|
|
in stdenv.mkDerivation rec {
|
|
name = "godot-${version}";
|
|
version = "3.0.4";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "godotengine";
|
|
repo = "godot";
|
|
rev = "${version}-stable";
|
|
sha256 = "0i4ssfb6igga9zwvsmahrnasx9cyqrsd6mlmssjgc482fy9q2kz4";
|
|
};
|
|
|
|
nativeBuildInputs = [ pkgconfig ];
|
|
buildInputs = [
|
|
scons libX11 libXcursor libXinerama libXrandr libXrender
|
|
libXi libXext libXfixes freetype openssl alsaLib libpulseaudio
|
|
libGLU zlib yasm
|
|
];
|
|
|
|
patches = [
|
|
./pkg_config_additions.patch
|
|
./dont_clobber_environment.patch
|
|
];
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
buildPhase = ''
|
|
scons target=release_debug platform=x11 prefix=$out -j $NIX_BUILD_CORES \
|
|
${lib.concatStringsSep " "
|
|
(lib.mapAttrsToList (k: v: "${k}=${builtins.toJSON v}") options)}
|
|
'';
|
|
|
|
outputs = [ "out" "dev" "man" ];
|
|
|
|
installPhase = ''
|
|
mkdir -p "$out/bin"
|
|
cp bin/godot.* $out/bin/godot
|
|
|
|
mkdir "$dev"
|
|
cp -r modules/gdnative/include $dev
|
|
|
|
mkdir -p "$man/share/man/man6"
|
|
cp misc/dist/linux/godot.6 "$man/share/man/man6/"
|
|
|
|
mkdir -p "$out"/share/{applications,icons/hicolor/scalable/apps}
|
|
cp misc/dist/linux/godot.desktop "$out/share/applications/"
|
|
cp icon.svg "$out/share/icons/hicolor/scalable/apps/godot.svg"
|
|
cp icon.png "$out/share/icons/godot.png"
|
|
substituteInPlace "$out/share/applications/godot.desktop" \
|
|
--replace "Exec=godot" "Exec=$out/bin/godot"
|
|
'';
|
|
|
|
meta = {
|
|
homepage = "https://godotengine.org";
|
|
description = "Free and Open Source 2D and 3D game engine";
|
|
license = stdenv.lib.licenses.mit;
|
|
platforms = [ "i686-linux" "x86_64-linux" ];
|
|
maintainers = [ stdenv.lib.maintainers.twey ];
|
|
};
|
|
}
|