forked from mirrors/nixpkgs
89023c38fc
I made a mistake merge. Reverting it inc778945806undid the state on master, but now I realize it crippled the git merge mechanism. As the merge contained a mix of commits from `master..staging-next` and other commits from `staging-next..staging`, it got the `staging-next` branch into a state that was difficult to recover. I reconstructed the "desired" state of staging-next tree by: - checking out the last commit of the problematic range:4effe769e2- `git rebase -i --preserve-merges a8a018ddc0` - dropping the mistaken merge commit and its revert from that range (while keeping reapplication from4effe769e2) - merging the last unaffected staging-next commit (803ca85c20) - fortunately no other commits have been pushed to staging-next yet - applying a diff on staging-next to get it into that state
93 lines
3.1 KiB
Nix
93 lines
3.1 KiB
Nix
{ lib
|
||
, python3
|
||
, stdenv
|
||
, writeTextDir
|
||
, substituteAll
|
||
, pkgsHostHost
|
||
, fetchpatch
|
||
}:
|
||
|
||
python3.pkgs.buildPythonApplication rec {
|
||
pname = "meson";
|
||
version = "0.55.3";
|
||
|
||
src = python3.pkgs.fetchPypi {
|
||
inherit pname version;
|
||
sha256 = "19cjy24mfaswxyvqmns6rd7hx05ybqb663zlgklspfr8l4jjmvbb";
|
||
};
|
||
|
||
patches = [
|
||
# Upstream insists on not allowing bindir and other dir options
|
||
# outside of prefix for some reason:
|
||
# https://github.com/mesonbuild/meson/issues/2561
|
||
# We remove the check so multiple outputs can work sanely.
|
||
./allow-dirs-outside-of-prefix.patch
|
||
|
||
# Meson is currently inspecting fewer variables than autoconf does, which
|
||
# makes it harder for us to use setup hooks, etc. Taken from
|
||
# https://github.com/mesonbuild/meson/pull/6827
|
||
./more-env-vars.patch
|
||
|
||
# Unlike libtool, vanilla Meson does not pass any information
|
||
# about the path library will be installed to to g-ir-scanner,
|
||
# breaking the GIR when path other than ${!outputLib}/lib is used.
|
||
# We patch Meson to add a --fallback-library-path argument with
|
||
# library install_dir to g-ir-scanner.
|
||
./gir-fallback-path.patch
|
||
|
||
# In common distributions, RPATH is only needed for internal libraries so
|
||
# meson removes everything else. With Nix, the locations of libraries
|
||
# are not as predictable, therefore we need to keep them in the RPATH.
|
||
# At the moment we are keeping the paths starting with /nix/store.
|
||
# https://github.com/NixOS/nixpkgs/issues/31222#issuecomment-365811634
|
||
(substituteAll {
|
||
src = ./fix-rpath.patch;
|
||
inherit (builtins) storeDir;
|
||
})
|
||
|
||
# When Meson removes build_rpath from DT_RUNPATH entry, it just writes
|
||
# the shorter NUL-terminated new rpath over the old one to reduce
|
||
# the risk of potentially breaking the ELF files.
|
||
# But this can cause much bigger problem for Nix as it can produce
|
||
# cut-in-half-by-\0 store path references.
|
||
# Let’s just clear the whole rpath and hope for the best.
|
||
./clear-old-rpath.patch
|
||
|
||
# Patch out default boost search paths to avoid impure builds on
|
||
# unsandboxed non-NixOS builds, see:
|
||
# https://github.com/NixOS/nixpkgs/issues/86131#issuecomment-711051774
|
||
./boost-Do-not-add-system-paths-on-nix.patch
|
||
];
|
||
|
||
setupHook = ./setup-hook.sh;
|
||
|
||
# Ensure there will always be a native C compiler when meson is used, as a
|
||
# workaround until https://github.com/mesonbuild/meson/pull/6512 lands.
|
||
depsHostHostPropagated = [ pkgsHostHost.stdenv.cc ];
|
||
|
||
# 0.45 update enabled tests but they are failing
|
||
doCheck = false;
|
||
# checkInputs = [ ninja pkgconfig ];
|
||
# checkPhase = "python ./run_project_tests.py";
|
||
|
||
postFixup = ''
|
||
pushd $out/bin
|
||
# undo shell wrapper as meson tools are called with python
|
||
for i in *; do
|
||
mv ".$i-wrapped" "$i"
|
||
done
|
||
popd
|
||
|
||
# Do not propagate Python
|
||
rm $out/nix-support/propagated-build-inputs
|
||
'';
|
||
|
||
meta = with lib; {
|
||
homepage = "https://mesonbuild.com";
|
||
description = "SCons-like build system that use python as a front-end language and Ninja as a building backend";
|
||
license = licenses.asl20;
|
||
maintainers = with maintainers; [ jtojnar mbe ];
|
||
platforms = platforms.all;
|
||
};
|
||
}
|