forked from mirrors/nixpkgs
46 lines
1.5 KiB
Nix
46 lines
1.5 KiB
Nix
{ stdenv, makeWrapper, fetchurl, elk5Version, nodejs, coreutils, which }:
|
|
|
|
with stdenv.lib;
|
|
let
|
|
inherit (builtins) elemAt;
|
|
archOverrides = {
|
|
"i686" = "x86";
|
|
};
|
|
info = splitString "-" stdenv.system;
|
|
arch = (elemAt info 0);
|
|
elasticArch = archOverrides."${arch}" or arch;
|
|
plat = elemAt info 1;
|
|
shas = {
|
|
"x86_64-linux" = "0b3kxd2s66pps5262khnh9yvp2mlwan6461ggxba380hfm7xxi6y";
|
|
"i686-linux" = "1vfl1xmzvrr064nbsbwr597r7hbxyh27397n981scgb1j1y7qja9";
|
|
"x86_64-darwin" = "19iw39qi7i8685s3mg3y6wsqnsddc6fj06g80vqbg76x8160z7dl";
|
|
};
|
|
in stdenv.mkDerivation rec {
|
|
name = "kibana-${version}";
|
|
version = elk5Version;
|
|
|
|
src = fetchurl {
|
|
url = "https://artifacts.elastic.co/downloads/kibana/${name}-${plat}-${elasticArch}.tar.gz";
|
|
sha256 = shas."${stdenv.system}" or (throw "Unknown architecture");
|
|
};
|
|
|
|
buildInputs = [ makeWrapper ];
|
|
|
|
installPhase = ''
|
|
mkdir -p $out/libexec/kibana $out/bin
|
|
mv * $out/libexec/kibana/
|
|
rm -r $out/libexec/kibana/node
|
|
makeWrapper $out/libexec/kibana/bin/kibana $out/bin/kibana \
|
|
--prefix PATH : "${stdenv.lib.makeBinPath [ nodejs coreutils which ]}"
|
|
sed -i 's@NODE=.*@NODE=${nodejs}/bin/node@' $out/libexec/kibana/bin/kibana
|
|
'';
|
|
|
|
meta = {
|
|
description = "Visualize logs and time-stamped data";
|
|
homepage = http://www.elasticsearch.org/overview/kibana;
|
|
license = licenses.asl20;
|
|
maintainers = with maintainers; [ offline rickynils ];
|
|
platforms = with platforms; unix;
|
|
};
|
|
}
|