forked from mirrors/nixpkgs
3227c1d215
${out} in configureFlags isn't expanded, so ncursesw5-config ends up
expanding ${out} at *runtime*. Here is the relevant ncursesw5-config
snippet showing how includedir gets its value at runtime.
bindir="${exec_prefix}/bin"
includedir="${out}/include"
libdir="${exec_prefix}/lib"
datadir="${prefix}/share"
mandir="${prefix}/man"
When running in a plain shell you get this:
$ ncursesw5-config --cflags
-I/include/ncursesw -I/include
And when run in a nix-build shell for e.g. gpsd:
$ ncursesw5-config --cflags
-I/nix/store/HASH-gpsd-3.10/include/ncursesw -I/nix/store/HASH-gpsd-3.10/include
This is clearly wrong.
Q: How come this has gone undetected for years?
A: It seems few packages use ncursesw5-config to get the compiler
flags. For example, our python curses module builds its own compiler
flags.
Fix this by moving the --includedir setting to preConfigure where shell
variables are expanded.
83 lines
2.9 KiB
Nix
83 lines
2.9 KiB
Nix
{stdenv, fetchurl, unicode ? true}:
|
|
|
|
let
|
|
/* C++ bindings fail to build on `i386-pc-solaris2.11' with GCC 3.4.3:
|
|
<http://bugs.opensolaris.org/bugdatabase/view_bug.do?bug_id=6395191>.
|
|
It seems that it could be worked around by #including <wchar.h> in the
|
|
right place, according to
|
|
<http://mail.python.org/pipermail/python-bugs-list/2006-September/035362.html>,
|
|
but this is left as an exercise to the reader.
|
|
So disable them for now. */
|
|
cxx = !stdenv.isSunOS;
|
|
in
|
|
stdenv.mkDerivation (rec {
|
|
name = "ncurses-5.9";
|
|
|
|
src = fetchurl {
|
|
url = "mirror://gnu/ncurses/${name}.tar.gz";
|
|
sha256 = "0fsn7xis81za62afan0vvm38bvgzg5wfmv1m86flqcj0nj7jjilh";
|
|
};
|
|
|
|
patches = [ ./patch-ac ];
|
|
|
|
configureFlags = ''
|
|
--with-shared --without-debug
|
|
${if unicode then "--enable-widec" else ""}${if cxx then "" else "--without-cxx-binding"}
|
|
'';
|
|
|
|
preConfigure = ''
|
|
export configureFlags="$configureFlags --includedir=$out/include"
|
|
'';
|
|
|
|
selfNativeBuildInput = true;
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
preBuild =
|
|
# On Darwin, we end up using the native `sed' during bootstrap, and it
|
|
# fails to run this command, which isn't needed anyway.
|
|
stdenv.lib.optionalString (!stdenv.isDarwin)
|
|
''sed -e "s@\([[:space:]]\)sh @\1''${SHELL} @" -i */Makefile Makefile'';
|
|
|
|
# When building a wide-character (Unicode) build, create backward
|
|
# compatibility links from the the "normal" libraries to the
|
|
# wide-character libraries (e.g. libncurses.so to libncursesw.so).
|
|
postInstall = if unicode then ''
|
|
${if cxx then "chmod 644 $out/lib/libncurses++w.a" else ""}
|
|
for lib in curses ncurses form panel menu; do
|
|
if test -e $out/lib/lib''${lib}w.a; then
|
|
rm -f $out/lib/lib$lib.so
|
|
echo "INPUT(-l''${lib}w)" > $out/lib/lib$lib.so
|
|
ln -svf lib''${lib}w.a $out/lib/lib$lib.a
|
|
ln -svf lib''${lib}w.so.5 $out/lib/lib$lib.so.5
|
|
fi
|
|
done;
|
|
ln -svf . $out/include/ncursesw
|
|
'' else "";
|
|
|
|
meta = {
|
|
description = "GNU Ncurses, a free software emulation of curses in SVR4 and more";
|
|
|
|
longDescription = ''
|
|
The Ncurses (new curses) library is a free software emulation of
|
|
curses in System V Release 4.0, and more. It uses Terminfo
|
|
format, supports pads and color and multiple highlights and
|
|
forms characters and function-key mapping, and has all the other
|
|
SYSV-curses enhancements over BSD Curses.
|
|
|
|
The ncurses code was developed under GNU/Linux. It has been in
|
|
use for some time with OpenBSD as the system curses library, and
|
|
on FreeBSD and NetBSD as an external package. It should port
|
|
easily to any ANSI/POSIX-conforming UNIX. It has even been
|
|
ported to OS/2 Warp!
|
|
'';
|
|
|
|
homepage = http://www.gnu.org/software/ncurses/;
|
|
|
|
license = "X11";
|
|
|
|
maintainers = [ stdenv.lib.maintainers.ludo ];
|
|
platforms = stdenv.lib.platforms.all;
|
|
};
|
|
} // ( if stdenv.isDarwin then { postFixup = "rm $out/lib/*.so"; } else { } ) )
|