forked from mirrors/nixpkgs
2e751c0772
the conversion procedure is simple: - find all things that look like options, ie calls to either `mkOption` or `lib.mkOption` that take an attrset. remember the attrset as the option - for all options, find a `description` attribute who's value is not a call to `mdDoc` or `lib.mdDoc` - textually convert the entire value of the attribute to MD with a few simple regexes (the set from mdize-module.sh) - if the change produced a change in the manual output, discard - if the change kept the manual unchanged, add some text to the description to make sure we've actually found an option. if the manual changes this time, keep the converted description this procedure converts 80% of nixos options to markdown. around 2000 options remain to be inspected, but most of those fail the "does not change the manual output check": currently the MD conversion process does not faithfully convert docbook tags like <code> and <package>, so any option using such tags will not be converted at all.
83 lines
2.3 KiB
Nix
83 lines
2.3 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let cfg = config.services.unclutter;
|
|
|
|
in {
|
|
options.services.unclutter = {
|
|
|
|
enable = mkOption {
|
|
description = lib.mdDoc "Enable unclutter to hide your mouse cursor when inactive";
|
|
type = types.bool;
|
|
default = false;
|
|
};
|
|
|
|
package = mkOption {
|
|
type = types.package;
|
|
default = pkgs.unclutter;
|
|
defaultText = literalExpression "pkgs.unclutter";
|
|
description = lib.mdDoc "unclutter derivation to use.";
|
|
};
|
|
|
|
keystroke = mkOption {
|
|
description = lib.mdDoc "Wait for a keystroke before hiding the cursor";
|
|
type = types.bool;
|
|
default = false;
|
|
};
|
|
|
|
timeout = mkOption {
|
|
description = lib.mdDoc "Number of seconds before the cursor is marked inactive";
|
|
type = types.int;
|
|
default = 1;
|
|
};
|
|
|
|
threshold = mkOption {
|
|
description = lib.mdDoc "Minimum number of pixels considered cursor movement";
|
|
type = types.int;
|
|
default = 1;
|
|
};
|
|
|
|
excluded = mkOption {
|
|
description = lib.mdDoc "Names of windows where unclutter should not apply";
|
|
type = types.listOf types.str;
|
|
default = [];
|
|
example = [ "" ];
|
|
};
|
|
|
|
extraOptions = mkOption {
|
|
description = lib.mdDoc "More arguments to pass to the unclutter command";
|
|
type = types.listOf types.str;
|
|
default = [];
|
|
example = [ "noevent" "grab" ];
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
systemd.user.services.unclutter = {
|
|
description = "unclutter";
|
|
wantedBy = [ "graphical-session.target" ];
|
|
partOf = [ "graphical-session.target" ];
|
|
serviceConfig.ExecStart = ''
|
|
${cfg.package}/bin/unclutter \
|
|
-idle ${toString cfg.timeout} \
|
|
-jitter ${toString (cfg.threshold - 1)} \
|
|
${optionalString cfg.keystroke "-keystroke"} \
|
|
${concatMapStrings (x: " -"+x) cfg.extraOptions} \
|
|
-not ${concatStringsSep " " cfg.excluded} \
|
|
'';
|
|
serviceConfig.PassEnvironment = "DISPLAY";
|
|
serviceConfig.RestartSec = 3;
|
|
serviceConfig.Restart = "always";
|
|
};
|
|
};
|
|
|
|
imports = [
|
|
(mkRenamedOptionModule [ "services" "unclutter" "threeshold" ]
|
|
[ "services" "unclutter" "threshold" ])
|
|
];
|
|
|
|
meta.maintainers = with lib.maintainers; [ rnhmjoj ];
|
|
|
|
}
|