forked from mirrors/nixpkgs
2e6bf42a22
There ver very many conflicts, basically all due to name -> pname+version. Fortunately, almost everything was auto-resolved by kdiff3, and for now I just fixed up a couple evaluation problems, as verified by the tarball job. There might be some fallback to these conflicts, but I believe it should be minimal. Hydra nixpkgs: ?compare=1538299
53 lines
1.6 KiB
Nix
53 lines
1.6 KiB
Nix
{ stdenv, fetchurl, cmake, extra-cmake-modules, pkgconfig, mkDerivation
|
|
, gtk2, qtbase, qtsvg, qtx11extras # Toolkit dependencies
|
|
, karchive, kconfig, kconfigwidgets, kio, frameworkintegration
|
|
, kguiaddons, ki18n, kwindowsystem, kdelibs4support, kiconthemes
|
|
, libpthreadstubs, pcre, libXdmcp, libX11, libXau # X11 dependencies
|
|
}:
|
|
|
|
let
|
|
version = "1.9";
|
|
in mkDerivation {
|
|
pname = "qtcurve";
|
|
inherit version;
|
|
src = fetchurl {
|
|
url = "http://download.kde.org/stable/qtcurve/qtcurve-${version}.tar.xz";
|
|
sha256 = "169gdny1cdld0qnx3nqvx568zjzdba4pwp3gxapc1hdh2cymw7r8";
|
|
};
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
nativeBuildInputs = [ cmake extra-cmake-modules pkgconfig ];
|
|
|
|
buildInputs = [
|
|
gtk2
|
|
qtbase qtsvg qtx11extras
|
|
karchive kconfig kconfigwidgets kio kiconthemes kguiaddons ki18n
|
|
kwindowsystem kdelibs4support frameworkintegration
|
|
libpthreadstubs
|
|
pcre
|
|
libXdmcp libX11 libXau
|
|
];
|
|
|
|
preConfigure = ''
|
|
for i in qt5/CMakeLists.txt qt5/config/CMakeLists.txt
|
|
do
|
|
substituteInPlace $i \
|
|
--replace "{_Qt5_PLUGIN_INSTALL_DIR}" "{KDE_INSTALL_QTPLUGINDIR}"
|
|
done
|
|
substituteInPlace CMakeLists.txt \
|
|
--replace \$\{GTK2_PREFIX\} $out
|
|
substituteInPlace gtk2/style/CMakeLists.txt \
|
|
--replace \$\{GTK2_LIBDIR\} $out/lib
|
|
patchShebangs tools/gen-version.sh
|
|
'';
|
|
|
|
meta = with stdenv.lib; {
|
|
homepage = https://github.com/QtCurve/qtcurve;
|
|
description = "Widget styles for Qt5/Plasma 5 and gtk2";
|
|
platforms = platforms.linux;
|
|
license = licenses.lgpl21Plus;
|
|
maintainers = [ maintainers.gnidorah ];
|
|
};
|
|
}
|