forked from mirrors/nixpkgs
4a7f99d55d
Part of: https://github.com/NixOS/nixpkgs/issues/108938 meta = with stdenv.lib; is a widely used pattern. We want to slowly remove the `stdenv.lib` indirection and encourage people to use `lib` directly. Thus let’s start with the meta field. This used a rewriting script to mostly automatically replace all occurances of this pattern, and add the `lib` argument to the package header if it doesn’t exist yet. The script in its current form is available at https://cs.tvl.fyi/depot@2f807d7f141068d2d60676a89213eaa5353ca6e0/-/blob/users/Profpatsch/nixpkgs-rewriter/default.nix
50 lines
1.8 KiB
Nix
50 lines
1.8 KiB
Nix
{ lib, stdenv, buildGoModule, fetchFromGitHub, nixosTests }:
|
|
|
|
buildGoModule rec {
|
|
pname = "consul";
|
|
version = "1.9.1";
|
|
rev = "v${version}";
|
|
|
|
# Note: Currently only release tags are supported, because they have the Consul UI
|
|
# vendored. See
|
|
# https://github.com/NixOS/nixpkgs/pull/48714#issuecomment-433454834
|
|
# If you want to use a non-release commit as `src`, you probably want to improve
|
|
# this derivation so that it can build the UI's JavaScript from source.
|
|
# See https://github.com/NixOS/nixpkgs/pull/49082 for something like that.
|
|
# Or, if you want to patch something that doesn't touch the UI, you may want
|
|
# to apply your changes as patches on top of a release commit.
|
|
src = fetchFromGitHub {
|
|
owner = "hashicorp";
|
|
repo = pname;
|
|
inherit rev;
|
|
sha256 = "06nw27crcrmz9p0hdc6g8ycq8p0kpbgf1g3i879f6h4jp4ca6zi3";
|
|
};
|
|
|
|
passthru.tests.consul = nixosTests.consul;
|
|
|
|
# This corresponds to paths with package main - normally unneeded but consul
|
|
# has a split module structure in one repo
|
|
subPackages = ["." "connect/certgen"];
|
|
|
|
vendorSha256 = "01fwbgdr4kxq4li83xxadl33ry1lkb3zhmcf2yrimfk042zabpck";
|
|
|
|
doCheck = false;
|
|
|
|
deleteVendor = true;
|
|
|
|
preBuild = ''
|
|
buildFlagsArray+=("-ldflags"
|
|
"-X github.com/hashicorp/consul/version.GitDescribe=v${version}
|
|
-X github.com/hashicorp/consul/version.Version=${version}
|
|
-X github.com/hashicorp/consul/version.VersionPrerelease=")
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Tool for service discovery, monitoring and configuration";
|
|
homepage = "https://www.consul.io/";
|
|
platforms = platforms.linux ++ platforms.darwin;
|
|
license = licenses.mpl20;
|
|
maintainers = with maintainers; [ pradeepchhetri vdemeester nh2 ];
|
|
};
|
|
}
|