forked from mirrors/nixpkgs
2e751c0772
the conversion procedure is simple: - find all things that look like options, ie calls to either `mkOption` or `lib.mkOption` that take an attrset. remember the attrset as the option - for all options, find a `description` attribute who's value is not a call to `mdDoc` or `lib.mdDoc` - textually convert the entire value of the attribute to MD with a few simple regexes (the set from mdize-module.sh) - if the change produced a change in the manual output, discard - if the change kept the manual unchanged, add some text to the description to make sure we've actually found an option. if the manual changes this time, keep the converted description this procedure converts 80% of nixos options to markdown. around 2000 options remain to be inspected, but most of those fail the "does not change the manual output check": currently the MD conversion process does not faithfully convert docbook tags like <code> and <package>, so any option using such tags will not be converted at all.
65 lines
1.7 KiB
Nix
65 lines
1.7 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
let cfg = config.services.vector;
|
|
|
|
in
|
|
{
|
|
options.services.vector = {
|
|
enable = mkEnableOption "Vector";
|
|
|
|
journaldAccess = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = lib.mdDoc ''
|
|
Enable Vector to access journald.
|
|
'';
|
|
};
|
|
|
|
settings = mkOption {
|
|
type = (pkgs.formats.json { }).type;
|
|
default = { };
|
|
description = lib.mdDoc ''
|
|
Specify the configuration for Vector in Nix.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
|
|
users.groups.vector = { };
|
|
users.users.vector = {
|
|
description = "Vector service user";
|
|
group = "vector";
|
|
isSystemUser = true;
|
|
};
|
|
systemd.services.vector = {
|
|
description = "Vector event and log aggregator";
|
|
wantedBy = [ "multi-user.target" ];
|
|
after = [ "network-online.target" ];
|
|
requires = [ "network-online.target" ];
|
|
serviceConfig =
|
|
let
|
|
format = pkgs.formats.toml { };
|
|
conf = format.generate "vector.toml" cfg.settings;
|
|
validateConfig = file:
|
|
pkgs.runCommand "validate-vector-conf" { } ''
|
|
${pkgs.vector}/bin/vector validate --no-environment "${file}"
|
|
ln -s "${file}" "$out"
|
|
'';
|
|
in
|
|
{
|
|
ExecStart = "${pkgs.vector}/bin/vector --config ${validateConfig conf}";
|
|
User = "vector";
|
|
Group = "vector";
|
|
Restart = "no";
|
|
StateDirectory = "vector";
|
|
ExecReload = "${pkgs.coreutils}/bin/kill -HUP $MAINPID";
|
|
AmbientCapabilities = "CAP_NET_BIND_SERVICE";
|
|
# This group is required for accessing journald.
|
|
SupplementaryGroups = mkIf cfg.journaldAccess "systemd-journal";
|
|
};
|
|
};
|
|
};
|
|
}
|