forked from mirrors/nixpkgs
2e751c0772
the conversion procedure is simple: - find all things that look like options, ie calls to either `mkOption` or `lib.mkOption` that take an attrset. remember the attrset as the option - for all options, find a `description` attribute who's value is not a call to `mdDoc` or `lib.mdDoc` - textually convert the entire value of the attribute to MD with a few simple regexes (the set from mdize-module.sh) - if the change produced a change in the manual output, discard - if the change kept the manual unchanged, add some text to the description to make sure we've actually found an option. if the manual changes this time, keep the converted description this procedure converts 80% of nixos options to markdown. around 2000 options remain to be inspected, but most of those fail the "does not change the manual output check": currently the MD conversion process does not faithfully convert docbook tags like <code> and <package>, so any option using such tags will not be converted at all.
131 lines
3.1 KiB
Nix
131 lines
3.1 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.services.syslogd;
|
|
|
|
syslogConf = pkgs.writeText "syslog.conf" ''
|
|
${if (cfg.tty != "") then "kern.warning;*.err;authpriv.none /dev/${cfg.tty}" else ""}
|
|
${cfg.defaultConfig}
|
|
${cfg.extraConfig}
|
|
'';
|
|
|
|
defaultConf = ''
|
|
# Send emergency messages to all users.
|
|
*.emerg *
|
|
|
|
# "local1" is used for dhcpd messages.
|
|
local1.* -/var/log/dhcpd
|
|
|
|
mail.* -/var/log/mail
|
|
|
|
*.=warning;*.=err -/var/log/warn
|
|
*.crit /var/log/warn
|
|
|
|
*.*;mail.none;local1.none -/var/log/messages
|
|
'';
|
|
|
|
in
|
|
|
|
{
|
|
###### interface
|
|
|
|
options = {
|
|
|
|
services.syslogd = {
|
|
|
|
enable = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = lib.mdDoc ''
|
|
Whether to enable syslogd. Note that systemd also logs
|
|
syslog messages, so you normally don't need to run syslogd.
|
|
'';
|
|
};
|
|
|
|
tty = mkOption {
|
|
type = types.str;
|
|
default = "tty10";
|
|
description = lib.mdDoc ''
|
|
The tty device on which syslogd will print important log
|
|
messages. Leave this option blank to disable tty logging.
|
|
'';
|
|
};
|
|
|
|
defaultConfig = mkOption {
|
|
type = types.lines;
|
|
default = defaultConf;
|
|
description = ''
|
|
The default <filename>syslog.conf</filename> file configures a
|
|
fairly standard setup of log files, which can be extended by
|
|
means of <varname>extraConfig</varname>.
|
|
'';
|
|
};
|
|
|
|
enableNetworkInput = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = lib.mdDoc ''
|
|
Accept logging through UDP. Option -r of syslogd(8).
|
|
'';
|
|
};
|
|
|
|
extraConfig = mkOption {
|
|
type = types.lines;
|
|
default = "";
|
|
example = "news.* -/var/log/news";
|
|
description = ''
|
|
Additional text appended to <filename>syslog.conf</filename>,
|
|
i.e. the contents of <varname>defaultConfig</varname>.
|
|
'';
|
|
};
|
|
|
|
extraParams = mkOption {
|
|
type = types.listOf types.str;
|
|
default = [ ];
|
|
example = [ "-m 0" ];
|
|
description = lib.mdDoc ''
|
|
Additional parameters passed to {command}`syslogd`.
|
|
'';
|
|
};
|
|
|
|
};
|
|
|
|
};
|
|
|
|
|
|
###### implementation
|
|
|
|
config = mkIf cfg.enable {
|
|
|
|
assertions =
|
|
[ { assertion = !config.services.rsyslogd.enable;
|
|
message = "rsyslogd conflicts with syslogd";
|
|
}
|
|
];
|
|
|
|
environment.systemPackages = [ pkgs.sysklogd ];
|
|
|
|
services.syslogd.extraParams = optional cfg.enableNetworkInput "-r";
|
|
|
|
# FIXME: restarting syslog seems to break journal logging.
|
|
systemd.services.syslog =
|
|
{ description = "Syslog Daemon";
|
|
|
|
requires = [ "syslog.socket" ];
|
|
|
|
wantedBy = [ "multi-user.target" ];
|
|
|
|
serviceConfig =
|
|
{ ExecStart = "${pkgs.sysklogd}/sbin/syslogd ${toString cfg.extraParams} -f ${syslogConf} -n";
|
|
# Prevent syslogd output looping back through journald.
|
|
StandardOutput = "null";
|
|
};
|
|
};
|
|
|
|
};
|
|
|
|
}
|