forked from mirrors/nixpkgs
8af12f8ebd
ChangeLog: https://github.com/grafana/grafana/releases/tag/v8.3.3
Note: I had to copy `defaults.ini` from the Git repo rather than from
`srcStatic`. This is because the `srcStatic`-variant missed some config
changes[1] which caused the test to fail like this:
postgresql # [ 24.754735] grafana-start[900]: Failed to start grafana. error: section "tracing.opentelemetry.jaeger" does not exist
postgresql # [ 24.756013] grafana-start[900]: section "tracing.opentelemetry.jaeger" does not exist
postgresql # [ 24.762057] systemd[1]: grafana.service: Main process exited, code=exited, status=1/FAILURE
postgresql # [ 24.765443] systemd[1]: grafana.service: Failed with result 'exit-code'.
postgresql # [ 24.767419] systemd[1]: grafana.service: Consumed 1.598s CPU time, no IP traffic.
[1] d993b12415 (diff-0c326c4f02797b088fc566e64fbfe2162390f52f2fec1483ec3a413a7f11c910)
80 lines
3.3 KiB
Nix
80 lines
3.3 KiB
Nix
{ lib, buildGo117Module, fetchurl, fetchFromGitHub, nixosTests, tzdata, wire }:
|
|
|
|
buildGo117Module rec {
|
|
pname = "grafana";
|
|
version = "8.3.3";
|
|
|
|
excludedPackages = "\\(alert_webhook_listener\\|clean-swagger\\|release_publisher\\|slow_proxy\\|slow_proxy_mac\\|macaron\\)";
|
|
|
|
src = fetchFromGitHub {
|
|
rev = "v${version}";
|
|
owner = "grafana";
|
|
repo = "grafana";
|
|
sha256 = "sha256-kfeYAEwHal5bfCmNe2l5iBLM4D3eYFaVtVhXdN90o+I=";
|
|
};
|
|
|
|
srcStatic = fetchurl {
|
|
url = "https://dl.grafana.com/oss/release/grafana-${version}.linux-amd64.tar.gz";
|
|
sha256 = "sha256-iUKMUg4AS8ufr3YY3UyB/2JJYGTL8urT4bnbz0dsbxg=";
|
|
};
|
|
|
|
vendorSha256 = "sha256-FHVlCL4ZyHO7Ebi31K1wXcMiN6hiQjVz+5jkJx8R7jc=";
|
|
|
|
nativeBuildInputs = [ wire ];
|
|
|
|
preBuild = ''
|
|
# Generate DI code that's required to compile the package.
|
|
# From https://github.com/grafana/grafana/blob/v8.2.3/Makefile#L33-L35
|
|
wire gen -tags oss ./pkg/server
|
|
wire gen -tags oss ./pkg/cmd/grafana-cli/runner
|
|
|
|
# The testcase makes an API call against grafana.com:
|
|
#
|
|
# [...]
|
|
# grafana> t=2021-12-02T14:24:58+0000 lvl=dbug msg="Failed to get latest.json repo from github.com" logger=update.checker error="Get \"https://raw.githubusercontent.com/grafana/grafana/main/latest.json\": dial tcp: lookup raw.githubusercontent.com on [::1]:53: read udp [::1]:36391->[::1]:53: read: connection refused"
|
|
# grafana> t=2021-12-02T14:24:58+0000 lvl=dbug msg="Failed to get plugins repo from grafana.com" logger=plugin.manager error="Get \"https://grafana.com/api/plugins/versioncheck?slugIn=&grafanaVersion=\": dial tcp: lookup grafana.com on [::1]:53: read udp [::1]:41796->[::1]:53: read: connection refused"
|
|
sed -i -e '/Request is not forbidden if from an admin/a t.Skip();' pkg/tests/api/plugins/api_plugins_test.go
|
|
|
|
# Skip a flaky test (https://github.com/NixOS/nixpkgs/pull/126928#issuecomment-861424128)
|
|
sed -i -e '/it should change folder successfully and return correct result/{N;s/$/\nt.Skip();/}'\
|
|
pkg/services/libraryelements/libraryelements_patch_test.go
|
|
|
|
|
|
# main module (github.com/grafana/grafana) does not contain package github.com/grafana/grafana/scripts/go
|
|
rm -r scripts/go
|
|
'';
|
|
|
|
ldflags = [
|
|
"-s" "-w" "-X main.version=${version}"
|
|
];
|
|
|
|
# Tests start http servers which need to bind to local addresses:
|
|
# panic: httptest: failed to listen on a port: listen tcp6 [::1]:0: bind: operation not permitted
|
|
__darwinAllowLocalNetworking = true;
|
|
|
|
# On Darwin, files under /usr/share/zoneinfo exist, but fail to open in sandbox:
|
|
# TestValueAsTimezone: date_formats_test.go:33: Invalid has err for input "Europe/Amsterdam": operation not permitted
|
|
preCheck = ''
|
|
export ZONEINFO=${tzdata}/share/zoneinfo
|
|
'';
|
|
|
|
postInstall = ''
|
|
tar -xvf $srcStatic
|
|
mkdir -p $out/share/grafana
|
|
mv grafana-*/{public,conf,tools} $out/share/grafana/
|
|
|
|
cp ./conf/defaults.ini $out/share/grafana/conf/
|
|
'';
|
|
|
|
passthru.tests = { inherit (nixosTests) grafana; };
|
|
|
|
meta = with lib; {
|
|
description = "Gorgeous metric viz, dashboards & editors for Graphite, InfluxDB & OpenTSDB";
|
|
license = licenses.agpl3;
|
|
homepage = "https://grafana.com";
|
|
maintainers = with maintainers; [ offline fpletz willibutz globin ma27 Frostman ];
|
|
platforms = platforms.linux ++ platforms.darwin;
|
|
mainProgram = "grafana-server";
|
|
};
|
|
}
|