forked from mirrors/nixpkgs
9ee5a5591d
Semi-automatic update generated by https://github.com/ryantm/nix-update tools. These checks were done: - built on NixOS - ran `/nix/store/cyjk3r8pig6cypvfv4fwx888ml4zd4vs-feh-2.25.1/bin/feh -h` got 0 exit code - ran `/nix/store/cyjk3r8pig6cypvfv4fwx888ml4zd4vs-feh-2.25.1/bin/feh --help` got 0 exit code - ran `/nix/store/cyjk3r8pig6cypvfv4fwx888ml4zd4vs-feh-2.25.1/bin/feh -v` and found version 2.25.1 - ran `/nix/store/cyjk3r8pig6cypvfv4fwx888ml4zd4vs-feh-2.25.1/bin/feh --version` and found version 2.25.1 - ran `/nix/store/cyjk3r8pig6cypvfv4fwx888ml4zd4vs-feh-2.25.1/bin/.feh-wrapped -h` got 0 exit code - ran `/nix/store/cyjk3r8pig6cypvfv4fwx888ml4zd4vs-feh-2.25.1/bin/.feh-wrapped --help` got 0 exit code - ran `/nix/store/cyjk3r8pig6cypvfv4fwx888ml4zd4vs-feh-2.25.1/bin/.feh-wrapped -v` and found version 2.25.1 - ran `/nix/store/cyjk3r8pig6cypvfv4fwx888ml4zd4vs-feh-2.25.1/bin/.feh-wrapped --version` and found version 2.25.1 - found 2.25.1 with grep in /nix/store/cyjk3r8pig6cypvfv4fwx888ml4zd4vs-feh-2.25.1 - directory tree listing: https://gist.github.com/6fb1817519334ef951e6661a3c41dda6
53 lines
1.3 KiB
Nix
53 lines
1.3 KiB
Nix
{ stdenv, fetchurl, makeWrapper
|
|
, xorg, imlib2, libjpeg, libpng
|
|
, curl, libexif, perlPackages }:
|
|
|
|
with stdenv.lib;
|
|
|
|
stdenv.mkDerivation rec {
|
|
name = "feh-${version}";
|
|
version = "2.25.1";
|
|
|
|
src = fetchurl {
|
|
url = "https://feh.finalrewind.org/${name}.tar.bz2";
|
|
sha256 = "197sm78bm33dvahr5nxqkbmpmdn4b13ahc9mrgn1l7n104bg4phc";
|
|
};
|
|
|
|
outputs = [ "out" "man" "doc" ];
|
|
|
|
nativeBuildInputs = [ makeWrapper xorg.libXt ]
|
|
++ optionals doCheck [ perlPackages.TestCommand perlPackages.TestHarness ];
|
|
|
|
buildInputs = [ xorg.libX11 xorg.libXinerama imlib2 libjpeg libpng curl libexif ];
|
|
|
|
makeFlags = [
|
|
"PREFIX=$(out)" "exif=1"
|
|
] ++ optional stdenv.isDarwin "verscmp=0";
|
|
|
|
postBuild = ''
|
|
pushd man
|
|
make
|
|
popd
|
|
'';
|
|
|
|
postInstall = ''
|
|
wrapProgram "$out/bin/feh" --prefix PATH : "${libjpeg.bin}/bin" \
|
|
--add-flags '--theme=feh'
|
|
install -D -m 644 man/*.1 $out/share/man/man1
|
|
'';
|
|
|
|
checkPhase = ''
|
|
PERL5LIB="${perlPackages.TestCommand}/lib/perl5/site_perl" make test
|
|
'';
|
|
|
|
doCheck = true;
|
|
|
|
meta = {
|
|
description = "A light-weight image viewer";
|
|
homepage = "https://feh.finalrewind.org/";
|
|
license = licenses.mit;
|
|
maintainers = [ maintainers.viric maintainers.willibutz ];
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|