forked from mirrors/nixpkgs
f7e390e6d4
Related: -9fc5e7e473-593e11fd94-508ae42a0fSince the last time I ran this script, the Repology API changed, so I had to adapt the script used in the previous PR. The new API should be more robust, so overall this is a positive (no more grepping the error messages for our relevant data but just a nice json structure). Here's the new script I used: ```sh curl https://repology.org/api/v1/repository/nix_unstable/problems \ | jq -r '.[] | select(.type == "homepage_permanent_https_redirect") | .data | "s@\(.url)@\(.target)@"' \ | sort | uniq | tee script.sed find -name '*.nix' | xargs -P4 -- sed -f script.sed -i ``` I will also add this script to `maintainers/scripts`.
61 lines
1.9 KiB
Nix
61 lines
1.9 KiB
Nix
{ stdenv, fetchurl, findutils, fixDarwinDylibNames
|
|
, sslSupport? true, openssl
|
|
}:
|
|
|
|
assert sslSupport -> openssl != null;
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "libevent";
|
|
version = "2.1.12";
|
|
|
|
src = fetchurl {
|
|
url = "https://github.com/libevent/libevent/releases/download/release-${version}-stable/libevent-${version}-stable.tar.gz";
|
|
sha256 = "1fq30imk8zd26x8066di3kpc5zyfc5z6frr3zll685zcx4dxxrlj";
|
|
};
|
|
|
|
# libevent_openssl is moved into its own output, so that openssl isn't present
|
|
# in the default closure.
|
|
outputs = [ "out" "dev" ]
|
|
++ stdenv.lib.optional sslSupport "openssl"
|
|
;
|
|
outputBin = "dev";
|
|
propagatedBuildOutputs = [ "out" ]
|
|
++ stdenv.lib.optional sslSupport "openssl"
|
|
;
|
|
|
|
buildInputs = []
|
|
++ stdenv.lib.optional sslSupport openssl
|
|
++ stdenv.lib.optional stdenv.isCygwin findutils
|
|
++ stdenv.lib.optional stdenv.isDarwin fixDarwinDylibNames
|
|
;
|
|
|
|
doCheck = false; # needs the net
|
|
|
|
postInstall = stdenv.lib.optionalString sslSupport ''
|
|
moveToOutput "lib/libevent_openssl*" "$openssl"
|
|
substituteInPlace "$dev/lib/pkgconfig/libevent_openssl.pc" \
|
|
--replace "$out" "$openssl"
|
|
sed "/^libdir=/s|$out|$openssl|" -i "$openssl"/lib/libevent_openssl.la
|
|
'';
|
|
|
|
enableParallelBuilding = true;
|
|
|
|
meta = with stdenv.lib; {
|
|
description = "Event notification library";
|
|
longDescription = ''
|
|
The libevent API provides a mechanism to execute a callback function
|
|
when a specific event occurs on a file descriptor or after a timeout
|
|
has been reached. Furthermore, libevent also support callbacks due
|
|
to signals or regular timeouts.
|
|
|
|
libevent is meant to replace the event loop found in event driven
|
|
network servers. An application just needs to call event_dispatch()
|
|
and then add or remove events dynamically without having to change
|
|
the event loop.
|
|
'';
|
|
homepage = "https://libevent.org/";
|
|
license = licenses.bsd3;
|
|
platforms = platforms.all;
|
|
};
|
|
}
|