forked from mirrors/nixpkgs
10cb4a8cf2
Conflicts: pkgs/development/libraries/gtk+/2.x.nix pkgs/development/libraries/libsamplerate/default.nix pkgs/development/libraries/libsndfile/default.nix pkgs/misc/cups/default.nix pkgs/top-level/all-packages.nix
60 lines
1.7 KiB
Nix
60 lines
1.7 KiB
Nix
{ stdenv, fetchurl, pkgconfig, zlib, libjpeg, libpng, libtiff, pam, openssl
|
|
, dbus, libusb, acl }:
|
|
|
|
let version = "1.5.4"; in
|
|
|
|
stdenv.mkDerivation {
|
|
name = "cups-${version}";
|
|
|
|
passthru = { inherit version; };
|
|
|
|
src = fetchurl {
|
|
url = "http://ftp.easysw.com/pub/cups/${version}/cups-${version}-source.tar.bz2";
|
|
md5 = "de3006e5cf1ee78a9c6145ce62c4e982";
|
|
};
|
|
|
|
# FIXME: Split off the cups client library.
|
|
outputs = [ "dev" "out" "doc" "man" ];
|
|
|
|
buildInputs = [ pkgconfig zlib libjpeg libpng libtiff libusb1 ]
|
|
++ stdenv.lib.optionals stdenv.isLinux [ pam dbus.libs acl ] ;
|
|
|
|
propagatedBuildInputs = [ openssl ];
|
|
|
|
configureFlags = "--localstatedir=/var --enable-dbus"; # --with-dbusdir
|
|
|
|
installFlags =
|
|
[ # Don't try to write in /var at build time.
|
|
"CACHEDIR=$(TMPDIR)/dummy"
|
|
"LOGDIR=$(TMPDIR)/dummy"
|
|
"REQUESTS=$(TMPDIR)/dummy"
|
|
"STATEDIR=$(TMPDIR)/dummy"
|
|
# Idem for /etc.
|
|
"PAMDIR=$(out)/etc/pam.d"
|
|
"DBUSDIR=$(out)/etc/dbus-1"
|
|
"INITDIR=$(out)/etc/rc.d"
|
|
"XINETD=$(out)/etc/xinetd.d"
|
|
# Idem for /usr.
|
|
"MENUDIR=$(out)/share/applications"
|
|
"ICONDIR=$(out)/share/icons"
|
|
# Work around a Makefile bug.
|
|
"CUPS_PRIMARY_SYSTEM_GROUP=root"
|
|
];
|
|
|
|
postInstall =
|
|
''
|
|
mkdir $dev/bin
|
|
mv $out/bin/cups-config $dev/bin/
|
|
|
|
chmod -R +w $out
|
|
'';
|
|
|
|
meta = {
|
|
homepage = "http://www.cups.org/";
|
|
description = "A standards-based printing system for UNIX";
|
|
license = stdenv.lib.licenses.gpl2; # actually LGPL for the library and GPL for the rest
|
|
maintainers = [ stdenv.lib.maintainers.urkud stdenv.lib.maintainers.simons ];
|
|
platforms = stdenv.lib.platforms.linux;
|
|
};
|
|
}
|