forked from mirrors/nixpkgs
2e751c0772
the conversion procedure is simple: - find all things that look like options, ie calls to either `mkOption` or `lib.mkOption` that take an attrset. remember the attrset as the option - for all options, find a `description` attribute who's value is not a call to `mdDoc` or `lib.mdDoc` - textually convert the entire value of the attribute to MD with a few simple regexes (the set from mdize-module.sh) - if the change produced a change in the manual output, discard - if the change kept the manual unchanged, add some text to the description to make sure we've actually found an option. if the manual changes this time, keep the converted description this procedure converts 80% of nixos options to markdown. around 2000 options remain to be inspected, but most of those fail the "does not change the manual output check": currently the MD conversion process does not faithfully convert docbook tags like <code> and <package>, so any option using such tags will not be converted at all.
115 lines
3.2 KiB
Nix
115 lines
3.2 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.services.soju;
|
|
stateDir = "/var/lib/soju";
|
|
listenCfg = concatMapStringsSep "\n" (l: "listen ${l}") cfg.listen;
|
|
tlsCfg = optionalString (cfg.tlsCertificate != null)
|
|
"tls ${cfg.tlsCertificate} ${cfg.tlsCertificateKey}";
|
|
logCfg = optionalString cfg.enableMessageLogging
|
|
"log fs ${stateDir}/logs";
|
|
|
|
configFile = pkgs.writeText "soju.conf" ''
|
|
${listenCfg}
|
|
hostname ${cfg.hostName}
|
|
${tlsCfg}
|
|
db sqlite3 ${stateDir}/soju.db
|
|
${logCfg}
|
|
http-origin ${concatStringsSep " " cfg.httpOrigins}
|
|
accept-proxy-ip ${concatStringsSep " " cfg.acceptProxyIP}
|
|
|
|
${cfg.extraConfig}
|
|
'';
|
|
in
|
|
{
|
|
###### interface
|
|
|
|
options.services.soju = {
|
|
enable = mkEnableOption "soju";
|
|
|
|
listen = mkOption {
|
|
type = types.listOf types.str;
|
|
default = [ ":6697" ];
|
|
description = ''
|
|
Where soju should listen for incoming connections. See the
|
|
<literal>listen</literal> directive in
|
|
<citerefentry><refentrytitle>soju</refentrytitle>
|
|
<manvolnum>1</manvolnum></citerefentry>.
|
|
'';
|
|
};
|
|
|
|
hostName = mkOption {
|
|
type = types.str;
|
|
default = config.networking.hostName;
|
|
defaultText = literalExpression "config.networking.hostName";
|
|
description = lib.mdDoc "Server hostname.";
|
|
};
|
|
|
|
tlsCertificate = mkOption {
|
|
type = types.nullOr types.path;
|
|
example = "/var/host.cert";
|
|
description = lib.mdDoc "Path to server TLS certificate.";
|
|
};
|
|
|
|
tlsCertificateKey = mkOption {
|
|
type = types.nullOr types.path;
|
|
example = "/var/host.key";
|
|
description = lib.mdDoc "Path to server TLS certificate key.";
|
|
};
|
|
|
|
enableMessageLogging = mkOption {
|
|
type = types.bool;
|
|
default = true;
|
|
description = lib.mdDoc "Whether to enable message logging.";
|
|
};
|
|
|
|
httpOrigins = mkOption {
|
|
type = types.listOf types.str;
|
|
default = [];
|
|
description = ''
|
|
List of allowed HTTP origins for WebSocket listeners. The parameters are
|
|
interpreted as shell patterns, see
|
|
<citerefentry><refentrytitle>glob</refentrytitle>
|
|
<manvolnum>7</manvolnum></citerefentry>.
|
|
'';
|
|
};
|
|
|
|
acceptProxyIP = mkOption {
|
|
type = types.listOf types.str;
|
|
default = [];
|
|
description = ''
|
|
Allow the specified IPs to act as a proxy. Proxys have the ability to
|
|
overwrite the remote and local connection addresses (via the X-Forwarded-\*
|
|
HTTP header fields). The special name "localhost" accepts the loopback
|
|
addresses 127.0.0.0/8 and ::1/128. By default, all IPs are rejected.
|
|
'';
|
|
};
|
|
|
|
extraConfig = mkOption {
|
|
type = types.lines;
|
|
default = "";
|
|
description = lib.mdDoc "Lines added verbatim to the configuration file.";
|
|
};
|
|
};
|
|
|
|
###### implementation
|
|
|
|
config = mkIf cfg.enable {
|
|
systemd.services.soju = {
|
|
description = "soju IRC bouncer";
|
|
wantedBy = [ "multi-user.target" ];
|
|
after = [ "network-online.target" ];
|
|
serviceConfig = {
|
|
DynamicUser = true;
|
|
Restart = "always";
|
|
ExecStart = "${pkgs.soju}/bin/soju -config ${configFile}";
|
|
StateDirectory = "soju";
|
|
};
|
|
};
|
|
};
|
|
|
|
meta.maintainers = with maintainers; [ malvo ];
|
|
}
|