forked from mirrors/nixpkgs
2e751c0772
the conversion procedure is simple: - find all things that look like options, ie calls to either `mkOption` or `lib.mkOption` that take an attrset. remember the attrset as the option - for all options, find a `description` attribute who's value is not a call to `mdDoc` or `lib.mdDoc` - textually convert the entire value of the attribute to MD with a few simple regexes (the set from mdize-module.sh) - if the change produced a change in the manual output, discard - if the change kept the manual unchanged, add some text to the description to make sure we've actually found an option. if the manual changes this time, keep the converted description this procedure converts 80% of nixos options to markdown. around 2000 options remain to be inspected, but most of those fail the "does not change the manual output check": currently the MD conversion process does not faithfully convert docbook tags like <code> and <package>, so any option using such tags will not be converted at all.
119 lines
3.6 KiB
Nix
119 lines
3.6 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
with lib;
|
|
let
|
|
inherit (config.security) wrapperDir;
|
|
cfg = config.services.kbfs;
|
|
|
|
in {
|
|
|
|
###### interface
|
|
|
|
options = {
|
|
|
|
services.kbfs = {
|
|
|
|
enable = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = lib.mdDoc "Whether to mount the Keybase filesystem.";
|
|
};
|
|
|
|
enableRedirector = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = lib.mdDoc ''
|
|
Whether to enable the Keybase root redirector service, allowing
|
|
any user to access KBFS files via `/keybase`,
|
|
which will show different contents depending on the requester.
|
|
'';
|
|
};
|
|
|
|
mountPoint = mkOption {
|
|
type = types.str;
|
|
default = "%h/keybase";
|
|
example = "/keybase";
|
|
description = lib.mdDoc "Mountpoint for the Keybase filesystem.";
|
|
};
|
|
|
|
extraFlags = mkOption {
|
|
type = types.listOf types.str;
|
|
default = [];
|
|
example = [
|
|
"-label kbfs"
|
|
"-mount-type normal"
|
|
];
|
|
description = lib.mdDoc ''
|
|
Additional flags to pass to the Keybase filesystem on launch.
|
|
'';
|
|
};
|
|
|
|
};
|
|
};
|
|
|
|
###### implementation
|
|
|
|
config = mkIf cfg.enable (mkMerge [
|
|
{
|
|
# Upstream: https://github.com/keybase/client/blob/master/packaging/linux/systemd/kbfs.service
|
|
systemd.user.services.kbfs = {
|
|
description = "Keybase File System";
|
|
|
|
# Note that the "Requires" directive will cause a unit to be restarted whenever its dependency is restarted.
|
|
# Do not issue a hard dependency on keybase, because kbfs can reconnect to a restarted service.
|
|
# Do not issue a hard dependency on keybase-redirector, because it's ok if it fails (e.g., if it is disabled).
|
|
wants = [ "keybase.service" ] ++ optional cfg.enableRedirector "keybase-redirector.service";
|
|
path = [ "/run/wrappers" ];
|
|
unitConfig.ConditionUser = "!@system";
|
|
|
|
serviceConfig = {
|
|
Type = "notify";
|
|
# Keybase notifies from a forked process
|
|
EnvironmentFile = [
|
|
"-%E/keybase/keybase.autogen.env"
|
|
"-%E/keybase/keybase.env"
|
|
];
|
|
ExecStartPre = [
|
|
"${pkgs.coreutils}/bin/mkdir -p \"${cfg.mountPoint}\""
|
|
"-${wrapperDir}/fusermount -uz \"${cfg.mountPoint}\""
|
|
];
|
|
ExecStart = "${pkgs.kbfs}/bin/kbfsfuse ${toString cfg.extraFlags} \"${cfg.mountPoint}\"";
|
|
ExecStop = "${wrapperDir}/fusermount -uz \"${cfg.mountPoint}\"";
|
|
Restart = "on-failure";
|
|
PrivateTmp = true;
|
|
};
|
|
wantedBy = [ "default.target" ];
|
|
};
|
|
|
|
services.keybase.enable = true;
|
|
|
|
environment.systemPackages = [ pkgs.kbfs ];
|
|
}
|
|
|
|
(mkIf cfg.enableRedirector {
|
|
security.wrappers."keybase-redirector".source = "${pkgs.kbfs}/bin/redirector";
|
|
|
|
systemd.tmpfiles.rules = [ "d /keybase 0755 root root 0" ];
|
|
|
|
# Upstream: https://github.com/keybase/client/blob/master/packaging/linux/systemd/keybase-redirector.service
|
|
systemd.user.services.keybase-redirector = {
|
|
description = "Keybase Root Redirector for KBFS";
|
|
wants = [ "keybase.service" ];
|
|
unitConfig.ConditionUser = "!@system";
|
|
|
|
serviceConfig = {
|
|
EnvironmentFile = [
|
|
"-%E/keybase/keybase.autogen.env"
|
|
"-%E/keybase/keybase.env"
|
|
];
|
|
# Note: The /keybase mount point is not currently configurable upstream.
|
|
ExecStart = "${wrapperDir}/keybase-redirector /keybase";
|
|
Restart = "on-failure";
|
|
PrivateTmp = true;
|
|
};
|
|
|
|
wantedBy = [ "default.target" ];
|
|
};
|
|
})
|
|
]);
|
|
}
|