forked from mirrors/nixpkgs
00e8e5b123
The default config.in template contains "include @sysconfdir@/sway/config.d/*" but we've dropped it to better support non-NixOS (which seems like a mistake in retrospect). This restores that behaviour and extends the default configuration via nixos.conf to fix #119445. Note: The security configurations (security.d) where dropped entirely (but maybe they'll return).
56 lines
1.5 KiB
Nix
56 lines
1.5 KiB
Nix
{ lib
|
|
, sway-unwrapped
|
|
, makeWrapper, symlinkJoin, writeShellScriptBin
|
|
, withBaseWrapper ? true, extraSessionCommands ? "", dbus
|
|
, withGtkWrapper ? false, wrapGAppsHook, gdk-pixbuf, glib, gtk3
|
|
, extraOptions ? [] # E.g.: [ "--verbose" ]
|
|
# Used by the NixOS module:
|
|
, isNixOS ? false
|
|
}:
|
|
|
|
assert extraSessionCommands != "" -> withBaseWrapper;
|
|
|
|
with lib;
|
|
|
|
let
|
|
sway = sway-unwrapped.override { inherit isNixOS; };
|
|
baseWrapper = writeShellScriptBin "sway" ''
|
|
set -o errexit
|
|
if [ ! "$_SWAY_WRAPPER_ALREADY_EXECUTED" ]; then
|
|
${extraSessionCommands}
|
|
export _SWAY_WRAPPER_ALREADY_EXECUTED=1
|
|
fi
|
|
if [ "$DBUS_SESSION_BUS_ADDRESS" ]; then
|
|
export DBUS_SESSION_BUS_ADDRESS
|
|
exec ${sway}/bin/sway "$@"
|
|
else
|
|
exec ${dbus}/bin/dbus-run-session ${sway}/bin/sway "$@"
|
|
fi
|
|
'';
|
|
in symlinkJoin {
|
|
name = "sway-${sway.version}";
|
|
|
|
paths = (optional withBaseWrapper baseWrapper)
|
|
++ [ sway ];
|
|
|
|
nativeBuildInputs = [ makeWrapper ]
|
|
++ (optional withGtkWrapper wrapGAppsHook);
|
|
|
|
buildInputs = optionals withGtkWrapper [ gdk-pixbuf glib gtk3 ];
|
|
|
|
# We want to run wrapProgram manually
|
|
dontWrapGApps = true;
|
|
|
|
postBuild = ''
|
|
${optionalString withGtkWrapper "gappsWrapperArgsHook"}
|
|
|
|
wrapProgram $out/bin/sway \
|
|
${optionalString withGtkWrapper ''"''${gappsWrapperArgs[@]}"''} \
|
|
${optionalString (extraOptions != []) "${concatMapStrings (x: " --add-flags " + x) extraOptions}"}
|
|
'';
|
|
|
|
passthru.providedSessions = [ "sway" ];
|
|
|
|
inherit (sway) meta;
|
|
}
|