From fe7292d81afb59bb23e16833f4eb3287c3b3a533 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Jos=C3=A9=20Romildo=20Malaquias?= <malaquias@gmail.com>
Date: Thu, 4 Jan 2018 16:22:35 -0200
Subject: [PATCH] mate-user-share: init at 1.18.0

---
 pkgs/desktops/mate/default.nix                |  2 +
 .../desktops/mate/mate-user-share/default.nix | 54 +++++++++++++++++++
 2 files changed, 56 insertions(+)
 create mode 100644 pkgs/desktops/mate/mate-user-share/default.nix

diff --git a/pkgs/desktops/mate/default.nix b/pkgs/desktops/mate/default.nix
index 3ece3feb55c0..0118b3fefff8 100644
--- a/pkgs/desktops/mate/default.nix
+++ b/pkgs/desktops/mate/default.nix
@@ -41,6 +41,7 @@ let
     mate-terminal = callPackage ./mate-terminal { };
     mate-themes = callPackage ./mate-themes { };
     mate-user-guide = callPackage ./mate-user-guide { };
+    mate-user-share = callPackage ./mate-user-share { };
     mate-utils = callPackage ./mate-utils { };
     pluma = callPackage ./pluma { };
 
@@ -81,6 +82,7 @@ let
       mate-system-monitor
       mate-terminal
       mate-user-guide
+      #mate-user-share
       mate-utils
       pluma
     ];
diff --git a/pkgs/desktops/mate/mate-user-share/default.nix b/pkgs/desktops/mate/mate-user-share/default.nix
new file mode 100644
index 000000000000..afacad527782
--- /dev/null
+++ b/pkgs/desktops/mate/mate-user-share/default.nix
@@ -0,0 +1,54 @@
+{ stdenv, fetchurl, pkgconfig, intltool, itstool, gtk3, dbus_glib, libnotify, libxml2, libcanberra_gtk3, caja, mod_dnssd, apacheHttpd, hicolor_icon_theme, wrapGAppsHook }:
+
+stdenv.mkDerivation rec {
+  name = "mate-user-share-${version}";
+  version = "${major-ver}.${minor-ver}";
+  major-ver = "1.18";
+  minor-ver = "0";
+
+  src = fetchurl {
+    url = "http://pub.mate-desktop.org/releases/${major-ver}/${name}.tar.xz";
+    sha256 = "0w7r7jmm12n41hcxj1pfk3f0xy69cddx7ga490x191rdpcb3ry1n";
+  };
+
+  nativeBuildInputs = [
+    pkgconfig
+    intltool
+    itstool
+    wrapGAppsHook
+  ];
+
+  buildInputs = [
+    gtk3
+    dbus_glib
+    libnotify
+    libcanberra_gtk3
+    libxml2
+    caja
+    hicolor_icon_theme
+    # Should mod_dnssd and apacheHttpd be runtime dependencies?
+    # In gnome-user-share they are not.
+    #mod_dnssd
+    #apacheHttpd
+  ];
+
+  preConfigure = ''
+    sed -e 's,^LoadModule dnssd_module.\+,LoadModule dnssd_module ${mod_dnssd}/modules/mod_dnssd.so,' \
+      -e 's,''${HTTP_MODULES_PATH},${apacheHttpd}/modules,' \
+      -i data/dav_user_2.4.conf
+  '';
+
+  configureFlags = [
+    "--with-httpd=${apacheHttpd.out}/bin/httpd"
+    "--with-modules-path=${apacheHttpd.dev}/modules"
+    "--with-cajadir=$(out)/lib/caja/extensions-2.0"
+  ];
+
+  meta = with stdenv.lib; {
+    description = "User level public file sharing for the MATE desktop";
+    homepage = https://github.com/mate-desktop/mate-user-share;
+    license = with licenses; [ gpl2Plus ];
+    platforms = platforms.unix;
+    maintainers = [ maintainers.romildo ];
+  };
+}