joycond-cemuhook: init at unstable-2023-08-09

nixos/modules/programs/joycond-cemuhook.nix

@@ -0,0 +1,17 @@
+{ lib, pkgs, config, ... }:
+with lib;
+{
+  options.programs.joycond-cemuhook = {
+    enable = mkEnableOption (lib.mdDoc "joycond-cemuhook, a program to enable support for cemuhook's UDP protocol for joycond devices.");
+  };
+
+  config = lib.mkIf config.programs.joycond-cemuhook.enable {
+    assertions = [
+      {
+        assertion = config.services.joycond.enable;
+        message = "joycond must be enabled through `services.joycond.enable`";
+      }
+    ];
+    environment.systemPackages = [ pkgs.joycond-cemuhook ];
+  };
+}

pkgs/by-name/jo/joycond-cemuhook/package.nix

@@ -0,0 +1,36 @@
+{ lib, python3Packages, fetchFromGitHub}:
+
+python3Packages.buildPythonApplication {
+  pname = "joycond-cemuhook";
+  pyproject = true;
+  version = "unstable-2023-08-09";
+
+  src = fetchFromGitHub {
+    owner = "joaorb64";
+    repo = "joycond-cemuhook";
+    rev = "3c0e07374ff431a0f8ae70dbb0b5a62fb3de06ee";
+    hash = "sha256-K24CEmYWhgkvVX4geg2bylH8TSvHIpsWjsPwY5BpquI=";
+  };
+
+  nativeBuildInputs = with python3Packages; [
+    setuptools
+    setuptools-git-versioning
+    setuptools-git
+  ];
+
+  propagatedBuildInputs = with python3Packages; [
+    dbus-python
+    evdev
+    pyudev
+    termcolor
+  ];
+
+  meta = with lib; {
+    homepage = "https://github.com/joaorb64/joycond-cemuhook";
+    description = "Support for cemuhook's UDP protocol for joycond devices";
+    license = licenses.mit;
+    maintainers = [ maintainers.noodlez1232 ];
+    mainProgram = "joycond-cemuhook";
+    platforms = platforms.linux;
+  };
+}