From ebe6b9669863c750ea9628088415ddb515d2d6d5 Mon Sep 17 00:00:00 2001
From: Eelco Dolstra <eelco.dolstra@logicblox.com>
Date: Thu, 6 Jun 2013 13:07:54 +0200
Subject: [PATCH] firefox: Update to 21.0
Only problem was that the chrome resources were not in the right place
(and you only see that by running with the -jsconsole flag).
---
.../networking/browsers/firefox/21.0.nix | 180 ++++++++++++++++++
pkgs/top-level/all-packages.nix | 9 +-
pkgs/top-level/release.nix | 2 +-
3 files changed, 189 insertions(+), 2 deletions(-)
create mode 100644 pkgs/applications/networking/browsers/firefox/21.0.nix
diff --git a/pkgs/applications/networking/browsers/firefox/21.0.nix b/pkgs/applications/networking/browsers/firefox/21.0.nix
new file mode 100644
index 000000000000..02766a9ccff6
--- /dev/null
+++ b/pkgs/applications/networking/browsers/firefox/21.0.nix
@@ -0,0 +1,180 @@
+{ stdenv, fetchurl, pkgconfig, gtk, pango, perl, python, zip, libIDL
+, libjpeg, libpng, zlib, cairo, dbus, dbus_glib, bzip2, xlibs
+, freetype, fontconfig, file, alsaLib, nspr, nss, libnotify
+, yasm, mesa, sqlite, unzip, makeWrapper, pysqlite
+
+, # If you want the resulting program to call itself "Firefox" instead
+ # of "Shiretoko" or whatever, enable this option. However, those
+ # binaries may not be distributed without permission from the
+ # Mozilla Foundation, see
+ # http://www.mozilla.org/foundation/trademarks/.
+ enableOfficialBranding ? false
+}:
+
+assert stdenv.gcc ? libc && stdenv.gcc.libc != null;
+
+rec {
+
+ firefoxVersion = "21.0";
+
+ xulVersion = "21.0"; # this attribute is used by other packages
+
+
+ src = fetchurl {
+ urls = [
+ # It is better to use this url for official releases, to take load off Mozilla's ftp server.
+ "http://releases.mozilla.org/pub/mozilla.org/firefox/releases/${firefoxVersion}/source/firefox-${firefoxVersion}.source.tar.bz2"
+ # Fall back to this url for versions not available at releases.mozilla.org.
+ "ftp://ftp.mozilla.org/pub/mozilla.org/firefox/releases/${firefoxVersion}/source/firefox-${firefoxVersion}.source.tar.bz2"
+ ];
+ sha1 = "e63b5488eaec1956947f59609d5839332ba7ffe1";
+ };
+
+ commonConfigureFlags =
+ [ "--enable-optimize"
+ #"--enable-profiling"
+ "--disable-debug"
+ "--enable-strip"
+ # "--with-system-jpeg" # Too old in nixpkgs
+ "--with-system-zlib"
+ "--with-system-bz2"
+ "--with-system-nspr"
+ "--with-system-nss"
+ # "--with-system-png" # <-- "--with-system-png won't work because the system's libpng doesn't have APNG support"
+ # "--enable-system-cairo" # <-- doesn't build
+ "--enable-system-sqlite"
+ "--disable-crashreporter"
+ "--disable-tests"
+ "--disable-necko-wifi" # maybe we want to enable this at some point
+ "--disable-installer"
+ "--disable-updater"
+ ];
+
+
+ xulrunner = stdenv.mkDerivation rec {
+ name = "xulrunner-${xulVersion}";
+
+ inherit src;
+
+ buildInputs =
+ [ pkgconfig gtk perl zip libIDL libjpeg libpng zlib cairo bzip2
+ python dbus dbus_glib pango freetype fontconfig xlibs.libXi
+ xlibs.libX11 xlibs.libXrender xlibs.libXft xlibs.libXt file
+ alsaLib nspr nss libnotify xlibs.pixman yasm mesa
+ xlibs.libXScrnSaver xlibs.scrnsaverproto pysqlite
+ xlibs.libXext xlibs.xextproto sqlite unzip makeWrapper
+ ];
+
+ configureFlags =
+ [ "--enable-application=xulrunner"
+ "--disable-javaxpcom"
+ ] ++ commonConfigureFlags;
+
+ enableParallelBuilding = true;
+
+ preConfigure =
+ ''
+ export NIX_LDFLAGS="$NIX_LDFLAGS -L$out/lib/xulrunner-${xulVersion}"
+
+ mkdir ../objdir
+ cd ../objdir
+ configureScript=../mozilla-release/configure
+ ''; # */
+
+ #installFlags = "SKIP_GRE_REGISTRATION=1";
+
+ postInstall = ''
+ # Fix run-mozilla.sh search
+ libDir=$(cd $out/lib && ls -d xulrunner-[0-9]*)
+ echo libDir: $libDir
+ test -n "$libDir"
+ cd $out/bin
+ rm xulrunner
+
+ for i in $out/lib/$libDir/*; do
+ file $i;
+ if file $i | grep executable &>/dev/null; then
+ echo -e '#! /bin/sh\nexec "'"$i"'" "$@"' > "$out/bin/$(basename "$i")";
+ chmod a+x "$out/bin/$(basename "$i")";
+ fi;
+ done
+ for i in $out/lib/$libDir/*.so; do
+ patchelf --set-rpath "$(patchelf --print-rpath "$i"):$out/lib/$libDir" $i || true
+ done
+ for i in $out/lib/$libDir/{plugin-container,xulrunner,xulrunner-stub}; do
+ wrapProgram $i --prefix LD_LIBRARY_PATH ':' "$out/lib/$libDir"
+ done
+ rm -f $out/bin/run-mozilla.sh
+ ''; # */
+
+ meta = {
+ description = "Mozilla Firefox XUL runner";
+ homepage = http://www.mozilla.com/en-US/firefox/;
+ };
+
+ passthru = { inherit gtk; version = xulVersion; };
+ };
+
+
+ firefox = stdenv.mkDerivation rec {
+ name = "firefox-${firefoxVersion}";
+
+ inherit src;
+
+ enableParallelBuilding = true;
+
+ buildInputs =
+ [ pkgconfig gtk perl zip libIDL libjpeg zlib cairo bzip2 python
+ dbus dbus_glib pango freetype fontconfig alsaLib nspr nss libnotify
+ xlibs.pixman yasm mesa sqlite file unzip pysqlite
+ ];
+
+ propagatedBuildInputs = [xulrunner];
+
+ configureFlags =
+ [ "--enable-application=browser"
+ "--with-libxul-sdk=${xulrunner}/lib/xulrunner-devel-${xulrunner.version}"
+ "--enable-chrome-format=jar"
+ "--disable-elf-hack"
+ ]
+ ++ commonConfigureFlags
+ ++ stdenv.lib.optional enableOfficialBranding "--enable-official-branding";
+
+ makeFlags = [
+ "SYSTEM_LIBXUL=1"
+ ];
+
+ # Hack to work around make's idea of -lbz2 dependency
+ preConfigure =
+ ''
+ find . -name Makefile.in -execdir sed -i '{}' -e '1ivpath %.so ${
+ stdenv.lib.concatStringsSep ":"
+ (map (s : s + "/lib") (buildInputs ++ [stdenv.gcc.libc]))
+ }' ';'
+ '';
+
+ postInstall =
+ ''
+ ln -s ${xulrunner}/lib/xulrunner-${xulrunner.version} $(echo $out/lib/firefox-*)/xulrunner
+ cd "$out/lib/"firefox-*
+ rm firefox
+ echo -e '#!${stdenv.shell}\nexec ${xulrunner}/bin/xulrunner "'"$PWD"'/application.ini" "$@"' > firefox
+ chmod a+x firefox
+
+ # Put chrome.manifest etc. in the right place.
+ mv browser/* .
+ rmdir browser
+ ''; # */
+
+ meta = {
+ description = "Mozilla Firefox - the browser, reloaded";
+ homepage = http://www.mozilla.com/en-US/firefox/;
+ maintainers = [ stdenv.lib.maintainers.eelco ];
+ };
+
+ passthru = {
+ inherit gtk xulrunner nspr;
+ isFirefox3Like = true;
+ };
+ };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 864b33e90d28..7692e9f53241 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -7221,7 +7221,7 @@ let
firefoxWrapper = wrapFirefox { browser = pkgs.firefox; };
- firefoxPkgs = pkgs.firefox20Pkgs;
+ firefoxPkgs = pkgs.firefox21Pkgs;
firefox36Pkgs = callPackage ../applications/networking/browsers/firefox/3.6.nix {
inherit (gnome) libIDL;
@@ -7242,6 +7242,13 @@ let
firefox20Wrapper = lowPrio (wrapFirefox { browser = firefox20Pkgs.firefox; });
+ firefox21Pkgs = callPackage ../applications/networking/browsers/firefox/21.0.nix {
+ inherit (gnome) libIDL;
+ inherit (pythonPackages) pysqlite;
+ };
+
+ firefox21Wrapper = lowPrio (wrapFirefox { browser = firefox21Pkgs.firefox; });
+
flac = callPackage ../applications/audio/flac { };
flashplayer = callPackage ../applications/networking/browsers/mozilla-plugins/flashplayer-11 {
diff --git a/pkgs/top-level/release.nix b/pkgs/top-level/release.nix
index de1aaec01ae2..bdc8cef87f30 100644
--- a/pkgs/top-level/release.nix
+++ b/pkgs/top-level/release.nix
@@ -360,7 +360,7 @@ let
};
firefox36Pkgs.firefox = linux;
- firefox20Pkgs.firefox = linux;
+ firefox21Pkgs.firefox = linux;
gnome = {
gnome_panel = linux;