Add Thrust 0.7.6

lib/maintainers.nix

@@ -151,6 +151,7 @@
   offline = "Jaka Hudoklin <jakahudoklin@gmail.com>";
   olcai = "Erik Timan <dev@timan.info>";
   orbitz = "Malcolm Matalka <mmatalka@gmail.com>";
+  osener = "Ozan Sener <ozan@ozansener.com>";
   page = "Carles Pagès <page@cubata.homelinux.net>";
   paholg = "Paho Lurie-Gregg <paho@paholg.com>";
   pakhfn = "Fedor Pakhomov <pakhfn@gmail.com>";

pkgs/development/tools/thrust/default.nix

@@ -0,0 +1,47 @@
+{ stdenv, fetchurl, buildEnv, makeWrapper, glib, alsaLib , dbus, gtk, atk
+, pango, freetype, fontconfig, gdk_pixbuf , cairo, cups, expat, nspr, gconf, nss
+, xlibs, libcap, unzip
+}:
+
+let
+  thrustEnv = buildEnv {
+    name = "env-thrust";
+    paths = [
+      stdenv.cc.gcc glib dbus gtk atk pango freetype fontconfig gdk_pixbuf
+      cairo cups expat alsaLib nspr gconf nss xlibs.libXrender xlibs.libX11
+      xlibs.libXext xlibs.libXdamage xlibs.libXtst xlibs.libXcomposite
+      xlibs.libXi xlibs.libXfixes xlibs.libXrandr xlibs.libXcursor libcap
+    ];
+  };
+in stdenv.mkDerivation rec {
+  name = "thrust-${version}";
+  version = "0.7.6";
+
+  src = fetchurl {
+    url = "https://github.com/breach/thrust/releases/download/v${version}/thrust-v${version}-linux-x64.zip";
+    sha256 = "07rrnlj0gk500pvar4b1wdqm05p4n9yjwn911x93bd2qwc8r5ymc";
+  };
+
+  buildInputs = [ thrustEnv makeWrapper unzip ];
+
+  phases = [ "installPhase" "fixupPhase" ];
+
+  installPhase = ''
+    mkdir -p $out/bin
+    mkdir -p $out/libexec/thrust
+    unzip -d $out/libexec/thrust/ $src
+    patchelf --set-interpreter "$(cat $NIX_CC/nix-support/dynamic-linker)" \
+      $out/libexec/thrust/thrust_shell
+    wrapProgram $out/libexec/thrust/thrust_shell \
+      --prefix "LD_LIBRARY_PATH" : "${thrustEnv}/lib:${thrustEnv}/lib64"
+    ln -s $out/libexec/thrust/thrust_shell $out/bin
+  '';
+
+  meta = with stdenv.lib; {
+    description = "Chromium-based cross-platform / cross-language application framework";
+    homepage = https://github.com/breach/thrust;
+    license = [ licenses.mit ];
+    maintainers = [ maintainers.osener ];
+    platforms = [ "x86_64-linux" ];
+  };
+}

pkgs/top-level/all-packages.nix

@@ -4480,6 +4480,10 @@ let
     omake = omake_rc1;
   };
   
+  thrust = callPackage ../development/tools/thrust {
+    gconf = pkgs.gnome.GConf;
+  };
+
   tinycc = callPackage ../development/compilers/tinycc { };
 
   urweb = callPackage ../development/compilers/urweb { };