kotlin-native: init at 1.5.31

pkgs/development/compilers/kotlin/native.nix

@@ -0,0 +1,64 @@
+{ lib
+, stdenv
+, fetchurl
+, jre
+, makeWrapper
+}:
+
+stdenv.mkDerivation rec {
+  pname = "kotlin-native";
+  version = "1.5.31";
+
+  src = let
+    getArch = {
+      "aarch64-darwin" = "macos-aarch64";
+      "x86_64-darwin" = "macos-x86_64";
+      "x86_64-linux" = "linux-x86_64";
+    }.${stdenv.system} or (throw "${pname}-${version}: ${stdenv.system} is unsupported.");
+
+    getUrl = version: arch:
+      "https://github.com/JetBrains/kotlin/releases/download/v${version}/kotlin-native-${arch}-${version}.tar.gz";
+
+    getHash = arch: {
+      "macos-aarch64" = "sha256-+9AF42AlPn1/8c14t8u+NN8FkoEmdt6tpmIKU9Rp2AM=";
+      "macos-x86_64" = "sha256-/eciSo4Eps2TTsv1XU1Rlm+KBmgQT0MWp2s/OAYtGt4=";
+      "linux-x86_64" = "sha256-Y2t+nlTu+j+h0oRneo7CJx0PmLAkqKYBJ+8go7rargM=";
+    }.${arch};
+  in
+    fetchurl {
+      url = getUrl version getArch;
+      hash = getHash getArch;
+    };
+
+  nativeBuildInputs = [
+    jre
+    makeWrapper
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out
+    mv * $out
+
+    runHook postInstall
+  '';
+
+  postFixup = ''
+    wrapProgram $out/bin/run_konan --prefix PATH ":" ${lib.makeBinPath [ jre ]}
+  '';
+
+  meta = {
+    homepage = "https://kotlinlang.org/";
+    description = "A modern programming language that makes developers happier";
+    longDescription = ''
+      Kotlin/Native is a technology for compiling Kotlin code to native
+      binaries, which can run without a virtual machine. It is an LLVM based
+      backend for the Kotlin compiler and native implementation of the Kotlin
+      standard library.
+    '';
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ ];
+    platforms = [ "x86_64-linux" ] ++ lib.platforms.darwin;
+  };
+}

pkgs/top-level/all-packages.nix

@@ -12273,6 +12273,7 @@ with pkgs;
   koka = haskell.lib.justStaticExecutables (haskellPackages.callPackage ../development/compilers/koka { });
 
   kotlin = callPackage ../development/compilers/kotlin { };
+  kotlin-native = callPackage ../development/compilers/kotlin/native.nix { };
 
   lazarus = callPackage ../development/compilers/fpc/lazarus.nix {
     fpc = fpc;