alioth/nixpkgs
3
0
Fork 0
forked from mirrors/nixpkgs
Code Releases Activity

nixos tests: add test for declarative containers, that container config changes

Browse source 
are applied on `nixos-rebuild switch` invocations.
This commit is contained in:
danbst 2017-08-23 12:43:07 +03:00
parent 65ff0d5f9d
commit 63f8122cd9
1 changed files with 66 additions and 0 deletions
Show stats Download patch file Download diff file Expand all files Collapse all files

66
nixos/tests/containers-reloadable.nix Normal file
View file

@ -0,0 +1,66 @@
import ./make-test.nix ({ pkgs, lib, ...} :
let
client_base = rec {
containers.test1 = {
autoStart = true;
config = {
environment.etc."check".text = "client_base";
};
};
# prevent make-test.nix to change IP
networking.interfaces = {
eth1.ip4 = lib.mkOverride 0 [ ];
};
};
in {
name = "cotnainers-reloadable";
meta = with pkgs.stdenv.lib.maintainers; {
maintainers = [ danbst ];
};
nodes = {
client = { lib, pkgs, ... }: {
imports = [ client_base ];
};
client_c1 = { lib, pkgs, ... }: {
imports = [ client_base ];
containers.test1.config = {
environment.etc."check".text = lib.mkForce "client_c1";
services.httpd.enable = true;
services.httpd.adminAddr = "nixos@example.com";
};
};
client_c2 = { lib, pkgs, ... }: {
imports = [ client_base ];
containers.test1.config = {
environment.etc."check".text = lib.mkForce "client_c2";
services.nginx.enable = true;
};
};
};
testScript = {nodes, ...}: let
originalSystem = nodes.client.config.system.build.toplevel;
c1System = nodes.client_c1.config.system.build.toplevel;
c2System = nodes.client_c2.config.system.build.toplevel;
in ''
$client->start();
$client->waitForUnit("default.target");
$client->succeed("[[ \$(nixos-container run test1 cat /etc/check) == client_base ]] >&2");
$client->succeed("${c1System}/bin/switch-to-configuration test >&2");
$client->succeed("[[ \$(nixos-container run test1 cat /etc/check) == client_c1 ]] >&2");
$client->succeed("systemctl status httpd -M test1 >&2");
$client->succeed("${c2System}/bin/switch-to-configuration test >&2");
$client->succeed("[[ \$(nixos-container run test1 cat /etc/check) == client_c2 ]] >&2");
$client->fail("systemctl status httpd -M test1 >&2");
$client->succeed("systemctl status nginx -M test1 >&2");
'';
})