From 4bcde3f244c64170a293d75773429834bb3e701a Mon Sep 17 00:00:00 2001
From: Anders Papitto <anderspapitto@gmail.com>
Date: Fri, 28 Aug 2015 14:27:55 -0700
Subject: [PATCH] spidermonkey: add 31.5

---
 .../interpreters/spidermonkey/31.5.nix        | 65 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  1 +
 2 files changed, 66 insertions(+)
 create mode 100644 pkgs/development/interpreters/spidermonkey/31.5.nix

diff --git a/pkgs/development/interpreters/spidermonkey/31.5.nix b/pkgs/development/interpreters/spidermonkey/31.5.nix
new file mode 100644
index 000000000000..4ee6658f59cd
--- /dev/null
+++ b/pkgs/development/interpreters/spidermonkey/31.5.nix
@@ -0,0 +1,65 @@
+{ stdenv, fetchurl, pkgconfig, perl, python, zip, libffi, readline }:
+
+stdenv.mkDerivation rec {
+  version = "31.5.0";
+  name = "spidermonkey-${version}";
+
+  # the release notes point to some guys home directory, see
+  # https://developer.mozilla.org/en-US/docs/Mozilla/Projects/SpiderMonkey/Releases/31
+  # probably it would be more ideal to pull a particular tag/revision
+  # from the mercurial repo
+  src = fetchurl {
+    url = "https://people.mozilla.org/~sstangl/mozjs-31.5.0.tar.bz2";
+    sha256 = "1q8icql5hh1g3gzg5fp4rl9rfagyhm9gilfn3dgi7qn4i1mrfqsd";
+  };
+
+  buildInputs = [ pkgconfig perl python zip libffi readline ];
+
+  postUnpack = "sourceRoot=\${sourceRoot}/js/src";
+
+  preConfigure = ''
+    export LIBXUL_DIST=$out
+  '';
+
+  configureFlags = [
+    "--enable-threadsafe"
+    "--with-system-ffi"
+    "--enable-readline"
+
+    # there is at least one unfixed issue building the tests, so I didn't bother
+    "--disable-tests"
+
+    # enabling these because they're wanted by 0ad. They may or may
+    # not be good defaults for other uses.
+    "--enable-gcgenerational"
+    "--enable-shared-js"
+
+    # Due to a build-system bug, this means the exact opposite of what it says.
+    # It is required by gcgenerational.
+    "--disable-exact-rooting"
+  ];
+
+  # This addresses some build system bug. It's quite likely to be safe
+  # to re-enable parallel builds if the source revision changes.
+  enableParallelBuilding = false;
+
+  # see comment by --disable-tests
+  doCheck = false;
+
+  postFixup = ''
+    # The headers are symlinks to a directory that doesn't get put
+    # into $out, so they end up broken. Fix that by just resolving the
+    # symlinks.
+    for i in $(find $out -type l); do
+      cp --remove-destination "$(readlink "$i")" "$i";
+    done
+  '';
+
+  meta = with stdenv.lib; {
+    description = "Mozilla's JavaScript engine written in C/C++";
+    homepage = https://developer.mozilla.org/en/SpiderMonkey;
+    # TODO: MPL/GPL/LGPL tri-license.
+
+    maintainers = [ maintainers.goibhniu ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 6b9a82edf334..5da3d0216cd8 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -5238,6 +5238,7 @@ let
   spidermonkey_185 = callPackage ../development/interpreters/spidermonkey/185-1.0.0.nix { };
   spidermonkey_17 = callPackage ../development/interpreters/spidermonkey/17.0.nix { };
   spidermonkey_24 = callPackage ../development/interpreters/spidermonkey/24.2.nix { };
+  spidermonkey_31 = callPackage ../development/interpreters/spidermonkey/31.5.nix { };
 
   supercollider = callPackage ../development/interpreters/supercollider {
     gcc = gcc48; # doesn't build with gcc49