openturns: init at 1.19

pkgs/development/libraries/dlib/default.nix

@@ -35,6 +35,6 @@ stdenv.mkDerivation rec {
     homepage = "http://www.dlib.net";
     license = licenses.boost;
     maintainers = with maintainers; [ christopherpoole ma27 ];
-    platforms = platforms.linux;
+    platforms = platforms.unix;
   };
 }

pkgs/development/libraries/openturns/default.nix

@@ -0,0 +1,80 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, cmake
+, swig
+, boost
+, spectra
+, libxml2
+, tbb
+, hmat-oss
+, nlopt
+, cminpack
+, ceres-solver
+, dlib
+, hdf5
+, primesieve
+, pagmo2
+, ipopt
+, Accelerate
+# tests take an hour to build on a 48-core machine
+, runTests ? false
+, enablePython ? false
+, python3Packages
+}:
+
+stdenv.mkDerivation rec {
+  pname = "openturns";
+  version = "1.19";
+
+  src = fetchFromGitHub {
+    owner = "openturns";
+    repo = "openturns";
+    rev = "v${version}";
+    sha256 = "sha256-hSvhKx7Ke5PXPYGcn9OJvq7YooAbHrbP6TdLZBotriE=";
+  };
+
+  nativeBuildInputs = [ cmake ] ++ lib.optional enablePython python3Packages.sphinx;
+  buildInputs = [
+    swig
+    boost
+    spectra
+    libxml2
+    tbb
+    hmat-oss
+    nlopt
+    cminpack
+    ceres-solver
+    dlib
+    hdf5
+    primesieve
+    pagmo2
+    ipopt
+  ] ++ lib.optionals enablePython [
+    python3Packages.python
+    python3Packages.matplotlib
+    python3Packages.psutil
+    python3Packages.dill
+  ] ++ lib.optional stdenv.isDarwin Accelerate;
+
+  cmakeFlags = [
+    "-DOPENTURNS_SYSCONFIG_PATH=$out/etc"
+    "-DCMAKE_UNITY_BUILD=ON"
+    "-DCMAKE_UNITY_BUILD_BATCH_SIZE=32"
+    "-DSWIG_COMPILE_FLAGS='-O1'"
+    "-DUSE_SPHINX=${if enablePython then "ON" else "OFF"}"
+    "-DBUILD_PYTHON=${if enablePython then "ON" else "OFF"}"
+  ];
+
+  doCheck = runTests;
+
+  checkTarget = "tests check";
+
+  meta = with lib; {
+    description = "Multivariate probabilistic modeling and uncertainty treatment library";
+    license = with licenses; [ lgpl3 gpl3 ];
+    homepage = "https://openturns.github.io/www/";
+    maintainers = with maintainers; [ gdinh ];
+    platforms = platforms.unix;
+  };
+}

pkgs/top-level/all-packages.nix

@@ -20762,6 +20762,10 @@ with pkgs;
 
   opensupaplex = callPackage ../games/opensupaplex { };
 
+  openturns = callPackage ../development/libraries/openturns {
+      inherit (darwin.apple_sdk.frameworks) Accelerate;
+  };
+
   open-wbo = callPackage ../applications/science/logic/open-wbo {};
 
   openwsman = callPackage ../development/libraries/openwsman {};

pkgs/top-level/python-packages.nix

@@ -6351,6 +6351,11 @@ in {
 
   opentimestamps = callPackage ../development/python-modules/opentimestamps { };
 
+  openturns = toPythonModule (pkgs.openturns.override {
+    python3Packages = self;
+    enablePython = true;
+  });
+
   opentracing = callPackage ../development/python-modules/opentracing { };
 
   openvino = toPythonModule (pkgs.openvino.override {