From 5da03fc60d934a14574335a569bbd3b69325bade Mon Sep 17 00:00:00 2001
From: Florian Klink <flokli@flokli.de>
Date: Sat, 16 Jan 2021 20:57:40 +0100
Subject: [PATCH] grafana-agent: init at 0.10.0

---
 .../monitoring/grafana-agent/default.nix      | 41 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  2 +
 2 files changed, 43 insertions(+)
 create mode 100644 pkgs/servers/monitoring/grafana-agent/default.nix

diff --git a/pkgs/servers/monitoring/grafana-agent/default.nix b/pkgs/servers/monitoring/grafana-agent/default.nix
new file mode 100644
index 000000000000..719733330639
--- /dev/null
+++ b/pkgs/servers/monitoring/grafana-agent/default.nix
@@ -0,0 +1,41 @@
+{ lib, buildGoModule, fetchFromGitHub, systemd }:
+
+buildGoModule rec {
+  pname = "grafana-agent";
+  version = "0.10.0";
+
+  src = fetchFromGitHub {
+    rev = "v${version}";
+    owner = "grafana";
+    repo = "agent";
+    sha256 = "1kliq6d3hg4bx9s5crdagirf2h3ljl0ikcyz0x0wb2ack6cgjsvm";
+  };
+
+  vendorSha256 = null;
+
+  # uses go-systemd, which uses libsystemd headers
+  # https://github.com/coreos/go-systemd/issues/351
+  NIX_CFLAGS_COMPILE = [ "-I${lib.getDev systemd}/include" ];
+
+  # tries to access /sys: https://github.com/grafana/agent/issues/333
+  preBuild = ''
+    rm pkg/integrations/node_exporter/node_exporter_test.go
+  '';
+
+  # go-systemd uses libsystemd under the hood, which does dlopen(libsystemd) at
+  # runtime.
+  # Add to RUNPATH so it can be found.
+  postFixup = ''
+    patchelf \
+      --set-rpath "${lib.makeLibraryPath [ (lib.getDev systemd) ]}:$(patchelf --print-rpath $out/bin/agent)" \
+      $out/bin/agent
+  '';
+
+  meta = with lib; {
+    description = "A lightweight subset of Prometheus and more, optimized for Grafana Cloud";
+    license = licenses.asl20;
+    homepage = "https://grafana.com/products/cloud";
+    maintainers = with maintainers; [ flokli ];
+    platforms = platforms.linux;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 355df6b465fb..40586feb5f53 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -17708,6 +17708,8 @@ in
   grafana = callPackage ../servers/monitoring/grafana { };
   grafanaPlugins = dontRecurseIntoAttrs (callPackage ../servers/monitoring/grafana/plugins { });
 
+  grafana-agent = callPackage ../servers/monitoring/grafana-agent { };
+
   grafana-loki = callPackage ../servers/monitoring/loki { };
 
   grafana_reporter = callPackage ../servers/monitoring/grafana-reporter { };