From 0b3b45c5a7ca319ea27337ab7c0f272102e07ff6 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Bj=C3=B8rn=20Forsman?= <bjorn.forsman@gmail.com>
Date: Wed, 25 May 2016 00:43:53 +0200
Subject: [PATCH] shutter: init at 0.93.1

Screenshot and annotation tool.

The application may complain about missing GConf dbus service[1], but it
still works (and remembers its settings, AFAICT).

[1]: The error message is (line wrapped):
  GConf Error: Failed to contact configuration server; the most
  common cause is a missing or misconfigured D-Bus session bus daemon. See
  http://projects.gnome.org/gconf/ for information. (Details -  1: GetIOR
  failed: GDBus.Error:org.freedesktop.DBus.Error.ServiceUnknown: The name
  org.gnome.GConf was not provided by any .service files)
---
 .../applications/graphics/shutter/default.nix | 41 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  2 +
 2 files changed, 43 insertions(+)
 create mode 100644 pkgs/applications/graphics/shutter/default.nix

diff --git a/pkgs/applications/graphics/shutter/default.nix b/pkgs/applications/graphics/shutter/default.nix
new file mode 100644
index 000000000000..59cea939bc9a
--- /dev/null
+++ b/pkgs/applications/graphics/shutter/default.nix
@@ -0,0 +1,41 @@
+{ stdenv, fetchurl, perl, perlPackages, makeWrapper, imagemagick, gdk_pixbuf, librsvg }:
+
+let
+  perlModules = with perlPackages;
+    [ Gnome2 Gnome2Canvas Gtk2 Glib Pango Gnome2VFS Gnome2Wnck Gtk2ImageView
+      Gtk2Unique FileWhich FileCopyRecursive XMLSimple NetDBus XMLTwig
+      XMLParser HTTPMessage ProcSimple SortNaturally LocaleGettext
+      ProcProcessTable URI ImageExifTool Gtk2AppIndicator LWPUserAgent JSON
+      PerlMagick WWWMechanize HTTPDate HTMLForm HTMLParser HTMLTagset JSONXS
+      CommonSense HTTPCookies NetOAuth PathClass GooCanvas X11Protocol Cairo
+    ];
+in
+stdenv.mkDerivation rec {
+  name = "shutter-0.93.1";
+
+  src = fetchurl {
+    url = "http://shutter-project.org/wp-content/uploads/releases/tars/${name}.tar.gz";
+    sha256 = "09cn3scwy98wqxkrjhnmxhpfnnynlbb41856yn5m3zwzqrxiyvak";
+  };
+
+  buildInputs = [ perl makeWrapper gdk_pixbuf librsvg ] ++ perlModules;
+
+  installPhase = ''
+    mkdir -p "$out"
+    cp -a . "$out"
+    (cd "$out" && mv CHANGES README COPYING "$out/share/doc/shutter")
+
+    wrapProgram $out/bin/shutter \
+      --set PERL5LIB "${stdenv.lib.makePerlPath perlModules}" \
+      --prefix PATH : "${imagemagick}/bin" \
+      --set GDK_PIXBUF_MODULE_FILE "$GDK_PIXBUF_MODULE_FILE"
+  '';
+
+  meta = with stdenv.lib; {
+    description = "Screenshot and annotation tool";
+    homepage = http://shutter-project.org/;
+    license = licenses.gpl3Plus;
+    platforms = platforms.all;
+    maintainers = [ maintainers.bjornfor ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 5a41c7cef8ec..eaead4807635 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -14013,6 +14013,8 @@ in
     gtk = gtk3;
   };
 
+  shutter = callPackage ../applications/graphics/shutter { };
+
   simple-scan = callPackage ../applications/graphics/simple-scan { };
 
   siproxd = callPackage ../applications/networking/siproxd { };